source: branches/working-0711/ccl/level-1/l1-readloop-lds.lisp @ 11832

Last change on this file since 11832 was 11804, checked in by gz, 11 years ago

If *toplevel-commands-dwim* is true, don't enter the debugger for errors during commands, just print a message and continue. In addition, for expressions that look like commands (i.e. keywords), explicitly complain of unknown command

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 28.2 KB
Line 
1;;;-*-Mode: LISP; Package: CCL -*-
2;;;
3;;;   Copyright (C) 1994-2001 Digitool, Inc
4;;;   This file is part of OpenMCL. 
5;;;
6;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
7;;;   License , known as the LLGPL and distributed with OpenMCL as the
8;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
9;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
10;;;   conflict, the preamble takes precedence. 
11;;;
12;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
13;;;
14;;;   The LLGPL is also available online at
15;;;   http://opensource.franz.com/preamble.html
16
17; l1-readloop-lds.lisp
18
19(in-package "CCL")
20
21
22
23(defun toplevel-loop ()
24  (loop
25    (if (eq (catch :toplevel 
26              (read-loop :break-level 0 )) $xstkover)
27      (format t "~&;[Stacks reset due to overflow.]")
28      (when (eq *current-process* *initial-process*)
29        (toplevel)))))
30
31
32(defvar *defined-toplevel-commands* ())
33(defvar *active-toplevel-commands* ())
34
35(defun %define-toplevel-command (group-name key name fn doc args)
36  (let* ((group (or (assoc group-name *defined-toplevel-commands*)
37                    (car (push (list group-name)
38                               *defined-toplevel-commands*))))
39         (pair (assoc key (cdr group) :test #'eq)))
40    (if pair
41      (rplacd pair (list* fn doc args))
42      (push (cons key (list* fn doc args)) (cdr group))))
43  name)
44
45(define-toplevel-command 
46    :global y (&optional p) "Yield control of terminal-input to process
47whose name or ID matches <p>, or to any process if <p> is null"
48    (%%yield-terminal-to (if p (find-process p))))      ;may be nil
49
50
51(define-toplevel-command
52    :global kill (p) "Kill process whose name or ID matches <p>"
53    (let* ((proc (find-process p)))
54      (if proc
55        (process-kill proc))))
56
57(define-toplevel-command 
58    :global proc (&optional p) "Show information about specified process <p>/all processes"
59    (flet ((show-process-info (proc)
60             (format t "~&~d : ~a ~a ~20t[~a] "
61                     (process-serial-number proc)
62                     (if (eq proc *current-process*)
63                       "->"
64                       "  ")
65                     (process-name proc)
66                     (process-whostate proc))
67             (let* ((suspend-count (process-suspend-count proc)))
68               (if (and suspend-count (not (eql 0 suspend-count)))
69                 (format t " (Suspended)")))
70             (let* ((terminal-input-shared-resource
71                     (if (typep *terminal-io* 'two-way-stream)
72                       (input-stream-shared-resource
73                        (two-way-stream-input-stream *terminal-io*)))))
74               (if (and terminal-input-shared-resource
75                        (%shared-resource-requestor-p
76                         terminal-input-shared-resource proc))
77                 (format t " (Requesting terminal input)")))
78             (fresh-line)))
79      (if p
80        (let* ((proc (find-process p)))
81          (if (null proc)
82            (format t "~&;; not found - ~s" p)
83            (show-process-info proc)))
84        (dolist (proc (all-processes) (values))
85          (show-process-info proc)))))
86
87(define-toplevel-command :global cd (dir) "Change to directory DIR" (setf (current-directory) dir) (toplevel-print (list (current-directory))))
88
89(define-toplevel-command :global pwd () "Print the pathame of the current directory" (toplevel-print (list (current-directory))))
90
91
92
93(defun list-restarts ()
94  (format *debug-io* "~&>   Type (:C <n>) to invoke one of the following restarts:")
95  (display-restarts))
96
97(define-toplevel-command :break pop () "exit current break loop" (abort-break))
98(define-toplevel-command :break a () "exit current break loop" (abort-break))
99(define-toplevel-command :break go () "continue" (continue))
100(define-toplevel-command :break q () "return to toplevel" (toplevel))
101(define-toplevel-command :break r () "list restarts" (list-restarts))
102
103(define-toplevel-command :break set (n frame value) "Set <n>th item of frame <frame> to <value>"
104  (let* ((frame-sp (nth-raw-frame frame *break-frame* nil)))
105    (if frame-sp
106        (toplevel-print (list (set-nth-value-in-frame frame-sp n nil value)))
107        (format *debug-io* "No frame with number ~D~%" frame))))
108
109(define-toplevel-command :break nframes ()
110  "print the number of stack frames accessible from this break loop"
111  (do* ((p *break-frame* (parent-frame p nil))
112        (i 0 (1+ i))
113        (last (last-frame-ptr)))
114      ((eql p last) (toplevel-print (list i)))))
115
116(define-toplevel-command :global ? () "help"
117  (format t "~&The following toplevel commands are available:")
118  (when *default-integer-command*
119    (format t "~& <n>  ~8Tthe same as (~s <n>)" (car *default-integer-command*)))
120  (dolist (g *active-toplevel-commands*)
121    (dolist (c (cdr g))
122      (let* ((command (car c))
123             (doc (caddr c))
124             (args (cdddr c)))
125        (if args
126          (format t "~& (~S~{ ~A~}) ~8T~A" command args doc)
127          (format t "~& ~S  ~8T~A" command doc)))))
128  (format t "~&Any other form is evaluated and its results are printed out."))
129
130
131(define-toplevel-command :break b (&key start count show-frame-contents) "backtrace"
132  (when *break-frame*
133      (print-call-history :detailed-p show-frame-contents
134                          :origin *break-frame*
135                          :count count
136                          :start-frame-number (or start 0))))
137
138(define-toplevel-command :break c (&optional n) "Choose restart <n>. If no <n>, continue"
139  (if n
140   (select-restart n)
141   (continue)))
142
143(define-toplevel-command :break f (n) "Show backtrace frame <n>"
144   (print-call-history :origin *break-frame*
145                       :start-frame-number n
146                       :count 1
147                       :detailed-p t))
148
149(define-toplevel-command :break return-from-frame (i &rest values) "Return VALUES from the I'th stack frame"
150  (let* ((frame-sp (nth-raw-frame  i *break-frame* nil)))
151    (if frame-sp
152      (apply #'return-from-frame frame-sp values))))
153
154(define-toplevel-command :break apply-in-frame (i function &rest args) "Applies FUNCTION to ARGS in the execution context of the Ith stack frame"
155  (let* ((frame-sp (nth-raw-frame  i *break-frame* nil)))
156    (if frame-sp
157      (apply-in-frame frame-sp function args))))
158                         
159                         
160
161(define-toplevel-command :break raw (n) "Show raw contents of backtrace frame <n>"
162   (print-call-history :origin *break-frame*
163                       :start-frame-number n
164                       :count 1
165                       :detailed-p :raw))
166
167(define-toplevel-command :break v (n frame-number) "Return value <n> in frame <frame-number>"
168  (let* ((frame-sp (nth-raw-frame frame-number *break-frame* nil)))
169    (if frame-sp
170      (toplevel-print (list (nth-value-in-frame frame-sp n nil))))))
171
172(define-toplevel-command :break arg (name frame-number) "Return value of argument named <name> in frame <frame-number>"
173  (let* ((frame-sp (nth-raw-frame frame-number *break-frame* nil)))
174    (when frame-sp
175      (multiple-value-bind (lfun pc) (cfp-lfun frame-sp)
176        (when (and lfun pc)
177          (let* ((unavailable (cons nil nil)))
178            (declare (dynamic-extent unavailable))
179            (let* ((value (arg-value nil frame-sp lfun pc unavailable name)))
180              (if (eq value unavailable)
181                (format *debug-io* "~&;; Can't determine value of ~s in frame ~s." name frame-number)
182                (toplevel-print (list value))))))))))
183
184(define-toplevel-command :break set-arg (name frame-number new) "Set value of argument named <name> in frame <frame-number> to value <new>."
185  (let* ((frame-sp (nth-raw-frame frame-number *break-frame* nil)))
186    (when frame-sp
187      (multiple-value-bind (lfun pc) (cfp-lfun frame-sp)
188        (when (and lfun pc)
189          (or (set-arg-value nil frame-sp lfun pc name new)
190              (format *debug-io* "~&;; Can't change value of ~s in frame ~s." name frame-number)))))))
191   
192
193(define-toplevel-command :break local (name frame-number) "Return value of local denoted by <name> in frame <frame-number> <name> can either be a symbol - in which case the most recent
194binding of that symbol is used - or an integer index into the frame's set of local bindings."
195  (let* ((frame-sp (nth-raw-frame frame-number *break-frame* nil)))
196    (when frame-sp
197      (multiple-value-bind (lfun pc) (cfp-lfun frame-sp)
198        (when (and lfun pc)
199          (let* ((unavailable (cons nil nil)))
200            (declare (dynamic-extent unavailable))
201            (let* ((value (local-value nil frame-sp lfun pc unavailable name)))
202              (if (eq value unavailable)
203                (format *debug-io* "~&;; Can't determine value of ~s in frame ~s." name frame-number)
204                (toplevel-print (list value))))))))))
205
206(define-toplevel-command :break set-local (name frame-number new) "Set value of argument denoted <name> (see :LOCAL) in frame <frame-number> to value <new>."
207  (let* ((frame-sp (nth-raw-frame frame-number *break-frame* nil)))
208    (when frame-sp
209      (multiple-value-bind (lfun pc) (cfp-lfun frame-sp)
210        (when (and lfun pc)
211          (or (set-local-value nil frame-sp lfun pc name new)
212              (format *debug-io* "~&;; Can't change value of ~s in frame ~s." name frame-number)))))))
213
214
215(define-toplevel-command :break form (frame-number)
216   "Return a form which looks like the call which established the stack frame identified by <frame-number>.  This is only well-defined in certain cases: when the function is globally named and not a lexical closure and when it was compiled with *SAVE-LOCAL-SYMBOLS* in effect."
217   (let* ((form (dbg-form frame-number)))
218     (when form
219       (let* ((*print-level* *backtrace-print-level*)
220              (*print-length* *backtrace-print-length*))
221         (toplevel-print (list form))))))
222
223;;; Ordinarily, form follows function.
224(define-toplevel-command :break function (frame-number)
225  "Returns the function invoked in backtrace frame <frame-number>.  This may be useful for, e.g., disassembly"
226  (let* ((cfp (nth-raw-frame frame-number *break-frame* nil)))
227    (when (and cfp (not (catch-csp-p cfp nil)))
228      (let* ((function (cfp-lfun cfp)))
229        (when function
230          (toplevel-print (list function)))))))
231 
232
233
234         
235
236 
237
238(defun %use-toplevel-commands (group-name)
239  ;; Push the whole group
240  (pushnew (assoc group-name *defined-toplevel-commands*)
241           *active-toplevel-commands*
242           :key #'(lambda (x) (car x))))  ; #'car not defined yet ...
243
244(%use-toplevel-commands :global)
245
246(defparameter *toplevel-commands-dwim* t
247 "If true, tries to interpret otherwise-erroneous toplevel expressions as commands.
248In addition, will suppress standard error handling for expressions that look like
249commands but aren't")
250
251(defvar *default-integer-command* nil
252  "If non-nil, should be (keyword  min max)), causing integers between min and max to be
253  interpreted as (keyword integer)")
254
255(defun check-toplevel-command (form)
256  (when (and *default-integer-command*
257             (integerp form)
258             (<= (cadr *default-integer-command*) form (caddr *default-integer-command*)))
259    (setq form `(,(car *default-integer-command*) ,form)))
260  (let* ((cmd (if (consp form) (car form) form))
261         (args (if (consp form) (cdr form))))
262    (when (or (keywordp cmd)
263              (and *toplevel-commands-dwim*
264                   (non-nil-symbol-p cmd)
265                   (not (if (consp form) (fboundp cmd) (boundp cmd)))
266                   ;; Use find-symbol so don't make unneeded keywords.
267                   (setq cmd (find-symbol (symbol-name cmd) :keyword))))
268      (when (eq cmd :help) (setq cmd :?))
269      (flet ((run (cmd form)
270               (or (dolist (g *active-toplevel-commands*)
271                     (let* ((pair (assoc cmd (cdr g))))
272                       (when pair 
273                         (apply (cadr pair) args)
274                         (return t))))
275                   ;; Try to detect user mistyping a command
276                   (when (and *toplevel-commands-dwim*
277                              (if (consp form)
278                                (and (keywordp (%car form)) (not (fboundp (%car form))))
279                                (keywordp form)))
280                     (error "Unknown command ~s" cmd)))))
281        (declare (dynamic-extent #'run))
282        (if *toplevel-commands-dwim*
283          (block nil
284            (handler-bind ((error (lambda (c)
285                                    (format t "~&~a" c)
286                                    (return t))))
287              (run cmd form)))
288          (run cmd form))))))
289
290(defparameter *quit-on-eof* nil)
291
292(defmethod stream-eof-transient-p (stream)
293  (let ((fd (stream-device stream :input)))
294    (and fd (eof-transient-p fd))))
295
296;;; This is the part common to toplevel loop and inner break loops.
297(defun read-loop (&key (input-stream *standard-input*)
298                       (output-stream *standard-output*)
299                       (break-level *break-level*)
300                       (prompt-function #'(lambda (stream)
301                                            (when (and *show-available-restarts* *break-condition*)
302                                              (list-restarts)
303                                              (setf *show-available-restarts* nil))
304                                            (print-listener-prompt stream t))))
305  (let* ((*break-level* break-level)
306         (*last-break-level* break-level)
307         *loading-file-source-file*
308         *in-read-loop*
309         *** ** * +++ ++ + /// // / -
310         (eof-value (cons nil nil))
311         (*show-available-restarts* (and *show-restarts-on-break* *break-condition*)))
312    (declare (dynamic-extent eof-value))
313    (loop
314      (restart-case
315       (catch :abort                    ;last resort...
316         (loop
317           (catch-cancel
318            (loop               
319              (setq *in-read-loop* nil
320                    *break-level* break-level)
321              (multiple-value-bind (form env print-result)
322                  (toplevel-read :input-stream input-stream
323                                 :output-stream output-stream
324                                 :prompt-function prompt-function
325                                 :eof-value eof-value)
326                (if (eq form eof-value)
327                  (if (and (not *batch-flag*)
328                           (not *quit-on-eof*)
329                           (stream-eof-transient-p input-stream))
330                    (progn
331                      (stream-clear-input input-stream)
332                      (abort-break))
333                    (exit-interactive-process *current-process*))
334                    (or (check-toplevel-command form)
335                        (let* ((values (toplevel-eval form env)))
336                          (if print-result (toplevel-print values))))))))
337           (format *terminal-io* "~&Cancelled")))
338       (abort () :report (lambda (stream)
339                           (if (eq break-level 0)
340                             (format stream "Return to toplevel.")
341                             (format stream "Return to break level ~D." break-level)))
342              #|                        ; Handled by interactive-abort
343                                        ; go up one more if abort occurred while awaiting/reading input               
344              (when (and *in-read-loop* (neq break-level 0))
345              (abort))
346              |#
347               )
348        (abort-break () 
349                     (unless (eq break-level 0)
350                       (abort))))
351       (clear-input input-stream)
352      (format output-stream "~%"))))
353
354;;; The first non-whitespace character available on INPUT-STREAM is a colon.
355;;; Try to interpret the line as a colon command (or possibly just a keyword.)
356(defun read-command-or-keyword (input-stream eof-value)
357  (let* ((line (read-line input-stream nil eof-value)))
358    (if (eq line eof-value)
359      eof-value
360      (let* ((in (make-string-input-stream line))
361             (keyword (read in nil eof-value)))
362        (if (eq keyword eof-value)
363          eof-value
364          (if (not (keywordp keyword))
365            keyword
366            (collect ((params))
367              (loop
368                (let* ((param (read in nil eof-value)))
369                  (if (eq param eof-value)
370                    (return
371                      (let* ((params (params)))
372                        (if params
373                          (cons keyword params)
374                          keyword)))
375                    (params (eval param))))))))))))
376
377;;; Read a form from the specified stream.
378(defun toplevel-read (&key (input-stream *standard-input*)
379                           (output-stream *standard-output*)
380                           (prompt-function #'print-listener-prompt)
381                           (eof-value *eof-value*))
382  (force-output output-stream)
383  (funcall prompt-function output-stream)
384  (read-toplevel-form input-stream eof-value))
385
386(defvar *always-eval-user-defvars* nil)
387
388(defun process-single-selection (form)
389  (if (and *always-eval-user-defvars*
390           (listp form) (eq (car form) 'defvar) (cddr form))
391    `(defparameter ,@(cdr form))
392    form))
393
394(defun toplevel-eval (form &optional env)
395  (destructuring-bind (vars . vals) (or env '(nil . nil))
396    (progv vars vals
397      (setq +++ ++ ++ + + - - form)
398      (unwind-protect
399           (let* ((package *package*)
400                  (values (multiple-value-list (cheap-eval-in-environment form nil))))
401             (unless (eq package *package*)
402               ;; If changing a local value (e.g. buffer-local), not useful to notify app
403               ;; without more info.  Perhaps should have a *source-context* that can send along?
404               (unless (member '*package* vars)
405                 (application-ui-operation *application* :note-current-package *package*)))
406             values)
407        (loop for var in vars as pval on vals
408              do (setf (car pval) (symbol-value var)))))))
409
410
411(defun toplevel-print (values &optional (out *standard-output*))
412  (setq /// // // / / values)
413  (unless (eq (car values) (%unbound-marker))
414    (setq *** ** ** * *  (%car values)))
415  (when values
416    (fresh-line out)
417    (dolist (val values) (write val :stream out) (terpri out))))
418
419(defparameter *listener-prompt-format* "~[?~:;~:*~d >~] ")
420
421 
422(defun print-listener-prompt (stream &optional (force t))
423  (unless *quiet-flag*
424    (when (or force (neq *break-level* *last-break-level*))
425      (let* ((*listener-indent* nil))
426        (fresh-line stream)
427        (format stream *listener-prompt-format* *break-level*))
428      (setq *last-break-level* *break-level*)))
429    (force-output stream))
430
431
432;;; Fairly crude default error-handlingbehavior, and a fairly crude mechanism
433;;; for customizing it.
434
435(defvar *app-error-handler-mode* :quit
436  "one of :quit, :quit-quietly, :listener might be useful.")
437
438(defmethod application-error ((a application) condition error-pointer)
439  (case *app-error-handler-mode*
440    (:listener   (break-loop-handle-error condition error-pointer))
441    (:quit-quietly (quit -1))
442    (:quit  (format t "~&Fatal error in ~s : ~a"
443                    (pathname-name (car *command-line-argument-list*))
444                    condition)
445                    (quit -1))))
446
447(defun make-application-error-handler (app mode)
448  (declare (ignore app))
449  (setq *app-error-handler-mode* mode))
450
451
452; You may want to do this anyway even if your application
453; does not otherwise wish to be a "lisp-development-system"
454(defmethod application-error ((a lisp-development-system) condition error-pointer)
455  (break-loop-handle-error condition error-pointer))
456
457(defun abnormal-application-exit ()
458  (ignore-errors
459    (print-call-history)
460    (force-output *debug-io*)
461    (quit -1))
462  (#__exit -1))
463
464(defun break-loop-handle-error (condition error-pointer)
465  (multiple-value-bind (bogus-globals newvals oldvals) (%check-error-globals)
466    (dolist (x bogus-globals)
467      (set x (funcall (pop newvals))))
468    (when (and *debugger-hook* *break-on-errors* (not *batch-flag*))
469      (let ((hook *debugger-hook*)
470            (*debugger-hook* nil))
471        (funcall hook condition hook)))
472    (%break-message "Error" condition error-pointer)
473    (let* ((s *error-output*))
474      (dolist (bogusness bogus-globals)
475        (let ((oldval (pop oldvals)))
476          (format s "~&;  NOTE: ~S was " bogusness)
477          (if (eq oldval (%unbound-marker-8))
478            (format s "unbound")
479            (format s "~s" oldval))
480          (format s ", was reset to ~s ." (symbol-value bogusness)))))
481    (if (and *break-on-errors* (not *batch-flag*))
482      (break-loop condition error-pointer)
483      (if *batch-flag*
484        (abnormal-application-exit)
485        (abort)))))
486
487(defun break (&optional string &rest args)
488  "Print a message and invoke the debugger without allowing any possibility
489   of condition handling occurring."
490  (if *batch-flag*
491    (apply #'error string args)
492    (apply #'%break-in-frame (%get-frame-ptr) string args)))
493
494(defun %break-in-frame (fp &optional string &rest args)
495  (flet ((do-break-loop ()
496           (let ((c (if (typep string 'condition)
497                      string
498                      (make-condition 'simple-condition
499                                    :format-control (or string "")
500                                    :format-arguments args))))
501             (cbreak-loop "Break" "Return from BREAK." c fp))))
502    (cond ((%i> *interrupt-level* -1)
503           (do-break-loop))
504          (*break-loop-when-uninterruptable*
505           (format *error-output* "Break while interrupt-level less than zero; binding to 0 during break-loop.")
506           (let ((interrupt-level (interrupt-level)))
507             (unwind-protect
508                  (progn
509                    (setf (interrupt-level) 0)
510                    (do-break-loop))
511               (setf (interrupt-level) interrupt-level))))
512          (t (format *error-output* "Break while interrupt-level less than zero; ignored.")))))
513
514
515(defun invoke-debugger (condition &aux (fp (%get-frame-ptr)))
516  "Enter the debugger."
517  (let ((c (require-type condition 'condition)))
518    (when *debugger-hook*
519      (let ((hook *debugger-hook*)
520            (*debugger-hook* nil))
521        (funcall hook c hook)))
522    (%break-message "Debug" c fp)
523    (break-loop c fp)))
524
525(defun %break-message (msg condition error-pointer &optional (prefixchar #\>))
526  (let ((*print-circle* *error-print-circle*)
527        ;(*print-prett*y nil)
528        (*print-array* nil)
529        (*print-escape* t)
530        (*print-gensym* t)
531        (*print-length* *error-print-length*)
532        (*print-level* *error-print-level*)
533        (*print-lines* nil)
534        (*print-miser-width* nil)
535        (*print-readably* nil)
536        (*print-right-margin* nil)
537        (*signal-printing-errors* nil)
538        (s (make-indenting-string-output-stream prefixchar nil)))
539    (format s "~A ~A: " prefixchar msg)
540    (setf (indenting-string-output-stream-indent s) (column s))
541    ;(format s "~A" condition) ; evil if circle
542    (report-condition condition s)
543    (if (not (and (typep condition 'simple-program-error)
544                  (simple-program-error-context condition)))
545      (format *error-output* "~&~A~%~A While executing: ~S"
546              (get-output-stream-string s) prefixchar (%real-err-fn-name error-pointer))
547      (format *error-output* "~&~A"
548              (get-output-stream-string s)))
549    (format *error-output* ", in process ~a(~d).~%" (process-name *current-process*) (process-serial-number *current-process*))
550  (force-output *error-output*)))
551                                        ; returns NIL
552
553(defun cbreak-loop (msg cont-string condition error-pointer)
554  (let* ((*print-readably* nil))
555    (%break-message msg condition error-pointer)
556    (restart-case (break-loop condition error-pointer)
557      (continue () :report (lambda (stream) (write-string cont-string stream))))
558    (fresh-line *error-output*)
559    nil))
560
561(defun warn (condition-or-format-string &rest args)
562  "Warn about a situation by signalling a condition formed by DATUM and
563   ARGUMENTS. While the condition is being signaled, a MUFFLE-WARNING restart
564   exists that causes WARN to immediately return NIL."
565  (when (typep condition-or-format-string 'condition)
566    (unless (typep condition-or-format-string 'warning)
567      (report-bad-arg condition-or-format-string 'warning))
568    (when args
569      (error 'type-error :datum args :expected-type 'null
570             :format-control "Extra arguments in ~s.")))
571  (let ((fp (%get-frame-ptr))
572        (c (require-type (condition-arg condition-or-format-string args 'simple-warning) 'warning)))
573    (when *break-on-warnings*
574      (cbreak-loop "Warning" "Signal the warning." c fp))
575    (restart-case (signal c)
576      (muffle-warning () :report "Skip the warning" (return-from warn nil)))
577    (%break-message (if (typep c 'compiler-warning) "Compiler warning" "Warning") c fp #\;)
578    ))
579
580(declaim (notinline select-backtrace))
581
582(defmacro new-backtrace-info (dialog youngest oldest tcr condition current fake db-link level)
583  (let* ((cond (gensym)))
584  `(let* ((,cond ,condition))
585    (vector ,dialog ,youngest ,oldest ,tcr (cons nil (compute-restarts ,cond)) (%catch-top ,tcr) ,cond ,current ,fake ,db-link ,level))))
586
587(defun select-backtrace ()
588  (declare (notinline select-backtrace))
589  ;(require 'new-backtrace)
590  (require :inspector)
591  (select-backtrace))
592
593(defvar *break-condition* nil "condition argument to innermost break-loop.")
594(defvar *break-frame* nil "frame-pointer arg to break-loop")
595(defvar *break-loop-when-uninterruptable* t)
596(defvar *show-restarts-on-break* #+ccl-0711 t #-ccl-0711 nil)
597(defvar *show-available-restarts* nil)
598
599(defvar *error-reentry-count* 0)
600
601(defun funcall-with-error-reentry-detection (thunk)
602  (let* ((count *error-reentry-count*)
603         (*error-reentry-count* (1+ count)))
604    (cond ((eql count 0) (funcall thunk))
605          ((eql count 1) (error "Error reporting error"))
606          (t (bug "Error reporting error")))))
607
608
609
610
611(defvar %last-continue% nil)
612(defun break-loop (condition frame-pointer)
613  "Never returns"
614  (let* ((%handlers% (last %handlers%)) ; firewall
615         (*break-frame* frame-pointer)
616         (*break-condition* condition)
617         (*compiling-file* nil)
618         (*backquote-stack* nil)
619         (continue (find-restart 'continue))
620         (*continuablep* (unless (eq %last-continue% continue) continue))
621         (%last-continue% continue)
622         (*standard-input* *debug-io*)
623         (*standard-output* *debug-io*)
624         (*signal-printing-errors* nil)
625         (*read-suppress* nil)
626         (*print-readably* nil)
627         (context (new-backtrace-info nil
628                                      frame-pointer
629                                      (if *backtrace-contexts*
630                                        (or (child-frame
631                                             (bt.youngest (car *backtrace-contexts*))
632                                             nil)
633                                            (last-frame-ptr))
634                                        (last-frame-ptr))
635                                      (%current-tcr)
636                                      condition
637                                      (%current-frame-ptr)
638                                      #+ppc-target *fake-stack-frames*
639                                      #+x86-target (%current-frame-ptr)
640                                      (db-link)
641                                      (1+ *break-level*)))
642         (*backtrace-contexts* (cons context *backtrace-contexts*)))
643    (with-terminal-input
644      (with-toplevel-commands :break
645        (if *continuablep*
646          (let* ((*print-circle* *error-print-circle*)
647                 (*print-level* *error-print-level*)
648                 (*print-length* *error-print-length*)
649                                        ;(*print-pretty* nil)
650                 (*print-array* nil))
651            (format t "~&> Type :GO to continue, :POP to abort, :R for a list of available restarts.")
652            (format t "~&> If continued: ~A~%" continue))
653          (format t "~&> Type :POP to abort, :R for a list of available restarts.~%"))
654        (format t "~&> Type :? for other options.")
655        (terpri)
656        (force-output)
657
658        (clear-input *debug-io*)
659        (setq *error-reentry-count* 0)  ; succesfully reported error
660        (ignoring-without-interrupts
661         (unwind-protect
662              (progn
663                (application-ui-operation *application*
664                                          :enter-backtrace-context context)
665                (read-loop :break-level (1+ *break-level*)
666                           :input-stream *debug-io*
667                           :output-stream *debug-io*))
668           (application-ui-operation *application* :exit-backtrace-context
669                                     context)))))))
670
671
672
673(defun display-restarts (&optional (condition *break-condition*))
674  (loop
675    for restart in (compute-restarts condition)
676    for count upfrom 0
677    do (format *debug-io* "~&~D. ~A" count restart)
678    finally (fresh-line *debug-io*)))
679
680(defun select-restart (n &optional (condition *break-condition*))
681  (let* ((restarts (compute-restarts condition)))
682    (invoke-restart-interactively
683     (nth (require-type n `(integer 0 (,(length restarts)))) restarts))))
684
685
686
687
688; End of l1-readloop-lds.lisp
Note: See TracBrowser for help on using the repository browser.