source: branches/working-0711/ccl/compiler/backend.lisp @ 12694

Last change on this file since 12694 was 12694, checked in by gz, 10 years ago

Merge r12579 r12590 r12591 r12594 r12600 from trunk - defcallback improvements

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 17.3 KB
Line 
1;;;-*- Mode: Lisp; Package: CCL -*-
2;;;
3;;;   Copyright (C) 1994-2001 Digitool, Inc
4;;;   This file is part of OpenMCL. 
5;;;
6;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
7;;;   License , known as the LLGPL and distributed with OpenMCL as the
8;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
9;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
10;;;   conflict, the preamble takes precedence. 
11;;;
12;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
13;;;
14;;;   The LLGPL is also available online at
15;;;   http://opensource.franz.com/preamble.html
16(in-package "CCL")
17
18(eval-when (:compile-toplevel :execute)
19  (require "ARCH"))
20
21(defconstant platform-word-size-mask 64)
22(defconstant platform-os-mask 7)
23(defconstant platform-cpu-mask (logandc2 (1- platform-word-size-mask)
24                                         platform-os-mask))
25(defconstant platform-word-size-32 0)
26(defconstant platform-word-size-64 64)
27(defconstant platform-cpu-ppc (ash 0 3))
28(defconstant platform-cpu-sparc (ash 1 3))
29(defconstant platform-cpu-x86 (ash 2 3))
30(defconstant platform-os-vxworks 0)
31(defconstant platform-os-linux 1)
32(defconstant platform-os-solaris 2)
33(defconstant platform-os-darwin 3)
34(defconstant platform-os-freebsd 4)
35(defconstant platform-os-windows 5)
36
37(defstruct backend
38  (name :a :type keyword)
39  (num-arg-regs 3 :type fixnum)    ; number of args passed in registers
40  (num-nvrs 0 :type fixnum)        ; number of callee-save node regs
41  (num-node-regs 0 :type fixnum)     ; number of node temps/arg regs
42  (lap-opcodes #() :type simple-vector)
43  (lookup-opcode #'false :type (or symbol function))
44  (lookup-macro #'false :type (or symbol function))
45  (p2-dispatch #() :type simple-vector)
46  (p2-compile 'error :type (or symbol function))
47  (p2-vinsn-templates (error "Missing arg") :type hash-table)
48  (p2-template-hash-name 'bogus :type symbol)
49  (target-specific-features () :type list)
50  (target-fasl-pathname "" :type (or string pathname))
51  (target-platform 0 :type fixnum)
52  (target-os ())
53  (target-arch-name nil :type symbol)
54  (target-foreign-type-data nil :type (or null foreign-type-data))
55  (lap-macros nil)
56  (target-arch nil)
57  (define-vinsn nil)
58  (platform-syscall-mask 0)
59  (define-callback nil)
60  (defcallback-body nil)
61  (lisp-context-register 0)
62  ;; difference between canonical static address for arch and this
63  ;; target's. Usually 0.
64  (lowmem-bias 0))
65
66(defmethod print-object ((b backend) s)
67  (print-unreadable-object (b s :type t :identity t)
68    (format s "~A" (backend-name b))))
69
70
71(defun target-os-name (&optional (backend *target-backend*))
72  (cdr (assoc (logand platform-os-mask (backend-target-platform backend))
73              *platform-os-names*)))
74
75
76(defparameter *backend-node-regs* 0)
77(defparameter *backend-node-temps* 0)
78(defparameter *available-backend-node-temps* 0)
79(defparameter *backend-imm-temps* 0)
80(defparameter *available-backend-imm-temps* 0)
81(defparameter *backend-fp-temps* 0)
82(defparameter *available-backend-fp-temps* 0)
83(defparameter *backend-crf-temps* 0)
84(defparameter *available-backend-crf-temps* 0)
85(defparameter *backend-allocate-high-node-temps* nil)
86
87(defparameter *mode-name-value-alist*
88  '((:lisp . 0)
89    (:u32 . 1)
90    (:s32 . 2)
91    (:u16 . 3)
92    (:s16 . 4)
93    (:u8 . 5)
94    (:s8 . 6)
95    (:address . 7)
96    (:u64 . 8)
97    (:s64 . 9)))
98
99(defun gpr-mode-name-value (name)
100  (if (eq name :natural)
101    (setq name
102          (target-word-size-case
103           (32 :u32)
104           (64 :u64)))
105    (if (eq name :signed-natural)
106      (setq name
107          (target-word-size-case
108           (32 :s32)
109           (64 :s64)))))
110  (or (cdr (assq name *mode-name-value-alist*))
111      (error "Unknown gpr mode name: ~s" name)))
112
113(defparameter *mode-specifier-types*
114  (vector
115   (specifier-type t)                   ;:lisp
116   (specifier-type '(unsigned-byte 32)) ;:u32
117   (specifier-type '(signed-byte 32))   ;:s32
118   (specifier-type '(unsigned-byte 16)) ;:u16
119   (specifier-type '(signed-byte 16))   ;:s16
120   (specifier-type '(unsigned-byte 8))  ;:u8
121   (specifier-type '(signed-byte 8))    ;:s8
122   (specifier-type 'macptr)             ;:address
123   (specifier-type '(unsigned-byte 64)) ;:u64
124   (specifier-type '(signed-byte 64)))) ;:s64
125
126(defun mode-specifier-type (mode-name)
127  (svref *mode-specifier-types* (gpr-mode-name-value mode-name)))
128   
129
130(defun use-node-temp (n)
131  (declare (fixnum n))
132  (if (logbitp n *available-backend-node-temps*)
133    (setq *available-backend-node-temps*
134          (logand *available-backend-node-temps* (lognot (ash 1 n)))))
135  n)
136
137(defun node-reg-p (reg)
138  (and (= (hard-regspec-class reg) hard-reg-class-gpr)
139       (= (get-regspec-mode reg) hard-reg-class-gpr-mode-node)))
140
141(defun node-reg-value (reg)
142  (if (node-reg-p reg)
143    (hard-regspec-value reg)))
144
145; if EA is a register-spec of the indicated class, return
146; the register #.
147(defun backend-ea-physical-reg (ea class)
148  (declare (fixnum class))
149  (and ea
150       (register-spec-p ea)
151       (= (hard-regspec-class ea) class)
152       (hard-regspec-value ea)))
153
154(defun backend-crf-p (vreg)
155  (backend-ea-physical-reg vreg hard-reg-class-crf))
156
157(defun available-node-temp (mask)
158  (if *backend-allocate-high-node-temps*
159    (do* ((bit 31 (1- bit)))
160         ((< bit 0) (error "Bug: ran out of node temp registers."))
161      (when (logbitp bit mask)
162        (return bit)))   
163    (dotimes (bit 32 (error "Bug: ran out of node temp registers."))
164      (when (logbitp bit mask)
165        (return bit)))))
166
167(defun ensure-node-target (reg)
168  (if (node-reg-p reg)
169    reg
170    (available-node-temp *available-backend-node-temps*)))
171
172(defun select-node-temp ()
173  (let* ((mask *available-backend-node-temps*))
174    (if *backend-allocate-high-node-temps*
175      (do* ((bit 31 (1- bit)))
176           ((< bit 0) (error "Bug: ran out of node temp registers."))
177        (when (logbitp bit mask)
178          (setq *available-backend-node-temps* (bitclr bit mask))
179          (return bit)))
180      (dotimes (bit 32 (error "Bug: ran out of node temp registers."))
181        (when (logbitp bit mask)
182          (setq *available-backend-node-temps* (bitclr bit mask))
183          (return bit))))))
184
185(defun available-imm-temp (mask &optional (mode-name :natural))
186  (dotimes (bit 32 (error "Bug: ran out of imm temp registers."))
187    (when (logbitp bit mask)
188      (return (set-regspec-mode bit (gpr-mode-name-value mode-name))))))
189
190(defun use-imm-temp (n)
191  (declare (fixnum n))
192  (setq *available-backend-imm-temps* (logand *available-backend-imm-temps* (lognot (ash 1 n))))
193  n)
194
195
196(defun select-imm-temp (&optional (mode-name :u32))
197  (let* ((mask *available-backend-imm-temps*))
198    (dotimes (bit 32 (error "Bug: ran out of imm temp registers."))
199      (when (logbitp bit mask)
200        (setq *available-backend-imm-temps* (bitclr bit mask))
201        (return (set-regspec-mode bit (gpr-mode-name-value mode-name)))))))
202
203;;; Condition-register fields are PPC-specific, but we might as well have
204;;; a portable interface to them.
205
206(defun use-crf-temp (n)
207  (declare (fixnum n))
208  (setq *available-backend-crf-temps* (logand *available-backend-crf-temps* (lognot (ash 1 (ash n -2)))))
209  n)
210
211(defun select-crf-temp ()
212  (let* ((mask *available-backend-crf-temps*))
213    (dotimes (bit 8 (error "Bug: ran out of CR fields."))
214      (declare (fixnum bit))
215      (when (logbitp bit mask)
216        (setq *available-backend-crf-temps* (bitclr bit mask))
217        (return (make-hard-crf-reg (the fixnum (ash bit 2))))))))
218
219(defun available-crf-temp (mask)
220  (dotimes (bit 8 (error "Bug: ran out of CR fields."))
221    (when (logbitp bit mask)
222      (return (make-hard-crf-reg (the fixnum (ash bit 2)))))))
223
224(defun single-float-reg-p (reg)
225  (and (= (hard-regspec-class reg) hard-reg-class-fpr)
226       (= (get-regspec-mode reg) hard-reg-class-fpr-mode-single)))
227
228(defun use-fp-temp (n)
229    (setq *available-backend-fp-temps* (logand *available-backend-fp-temps* (lognot (ash 1 n))))
230    n)
231
232(defun available-fp-temp (mask &optional (mode-name :double-float))
233  (dotimes (bit (integer-length mask) (error "Bug: ran out of node fp registers."))
234    (when (logbitp bit mask)
235      (let* ((mode (if (eq mode-name :double-float) 
236                     hard-reg-class-fpr-mode-double
237                     hard-reg-class-fpr-mode-single)))
238        (return (make-hard-fp-reg bit mode))))))
239
240(defparameter *backend-all-lregs* ())
241(defun note-logical-register (l)
242  (push l *backend-all-lregs*)
243  l)
244
245(defun free-logical-registers ()
246  (without-interrupts
247   (let* ((prev (pool.data *lreg-freelist*)))
248     (dolist (r *backend-all-lregs*)
249       (setf (lreg-value r) prev
250             prev r))
251     (setf (pool.data *lreg-freelist*) prev)
252     (setq *backend-all-lregs* nil))))
253
254
255(defun make-unwired-lreg (value &key 
256                                (class (if value (hard-regspec-class value) 0))
257                                (mode (if value (get-regspec-mode value) 0))
258                                (type (if value (get-node-regspec-type-modes value) 0)))
259  (note-logical-register (make-lreg (if value (hard-regspec-value value)) class mode type nil)))
260
261;;; Make an lreg with the same class, mode, & type as the prototype.
262(defun make-unwired-lreg-like (proto)
263  (make-unwired-lreg nil
264                     :class (hard-regspec-class proto)
265                     :mode (get-regspec-mode proto)
266                     :type (get-node-regspec-type-modes proto)))
267 
268(defun make-wired-lreg (value &key 
269                              (class (hard-regspec-class value))
270                              (mode (get-regspec-mode value))
271                              (type (get-node-regspec-type-modes value)))
272  (note-logical-register (make-lreg (hard-regspec-value value) class mode type t)))
273
274(defvar *backend-immediates*)
275
276(defun backend-new-immediate (imm)
277  (vector-push-extend imm *backend-immediates*))
278
279(defun backend-immediate-index (imm)
280  (or (position imm *backend-immediates*)
281      (backend-new-immediate imm)))
282
283(defvar *backend-vinsns*)
284
285(defvar *backend-labels*)
286
287(defun backend-gen-label (seg labelnum)
288  (append-dll-node (aref *backend-labels* labelnum) seg)
289  labelnum)
290
291(defconstant $backend-compound-branch-target-bit 18)
292(defconstant $backend-compound-branch-target-mask (ash 1 $backend-compound-branch-target-bit))
293
294(defconstant $backend-mvpass-bit 19)
295(defconstant $backend-mvpass-mask (ash 1 $backend-mvpass-bit))
296
297(defconstant $backend-return (- (ash 1 18) 1))
298(defconstant $backend-mvpass (- (ash 1 18) 2))
299
300(defconstant $backend-compound-branch-false-byte (byte 18 0))
301(defconstant $backend-compound-branch-true-byte (byte 18 20))
302
303
304(defun backend-get-next-label ()
305  (let* ((lnum (length *backend-labels*)))
306    (if (>= lnum $backend-mvpass)
307      (compiler-function-overflow)
308      (vector-push-extend (make-vinsn-label lnum) *backend-labels*))))
309
310
311;;; Loop through all labels in *backend-labels*; if the label has been
312;;; emitted, remove it from vinsns and return it to the
313;;; *vinsn-label-freelist*.  "vinsns" should then contain nothing but
314;;; ... vinsns
315
316(defun backend-remove-labels ()
317  (let* ((labels *backend-labels*)
318         (freelist *vinsn-label-freelist*))
319    (dotimes (i (the fixnum (length labels)))
320      (let* ((lab (aref labels i)))
321        (if lab
322          (if (vinsn-label-succ lab)
323            (remove-and-free-dll-node lab freelist)
324            (free-dll-node lab freelist)))))))
325
326(defun backend-copy-label (from to)
327  (let* ((from-lab (aref *backend-labels* from))
328         (to-lab (aref *backend-labels* to)))
329    (when (null (vinsn-label-succ from-lab))
330      (error "Copy label: not defined yet!"))
331    (backend-merge-labels from-lab to-lab)
332    (setf (aref *backend-labels* to) from-lab)))
333
334(defun backend-merge-labels (from-lab to-lab)
335  (let* ((to-refs (vinsn-label-refs to-lab)))
336    (when to-refs
337      ;; Make all extant refs to TO-LAB refer to FROM-LAB
338      (setf (vinsn-label-refs to-lab) nil)
339      (dolist (vinsn to-refs)
340        (push vinsn (vinsn-label-refs from-lab))
341        (let* ((vp (vinsn-variable-parts vinsn)))
342          (declare (simple-vector vp))
343          (dotimes (i (the fixnum (length vp)))
344            (when (eq to-lab (svref vp i))
345              (setf (svref vp i) from-lab))))))))
346
347;;; For now, the register-spec must be
348;;; a) non-nil
349;;; c) of an expected class.
350;;; Return the class and value.
351(defun regspec-class-and-value (regspec expected)
352  (declare (fixnum expected))
353  (let* ((class (hard-regspec-class regspec)))
354    (declare (type (unsigned-byte 8) class))
355    (if (logbitp class expected)
356      (values class (if (typep regspec 'lreg)
357                      regspec
358                      (hard-regspec-value regspec)))
359      (error "bug: Register spec class (~d) is not one  of ~s." class expected))))
360
361(defmacro with-node-temps ((&rest reserved) (&rest nodevars) &body body)
362  `(let* ((*available-backend-node-temps* (logand *available-backend-node-temps* (lognot (logior ,@(mapcar #'(lambda (r) `(ash 1 (hard-regspec-value ,r))) reserved)))))
363          ,@(mapcar #'(lambda (v) `(,v (make-unwired-lreg (select-node-temp)))) nodevars))
364     ,@body))
365
366(defmacro with-imm-temps ((&rest reserved) (&rest immvars) &body body)
367  `(let* ((*available-backend-imm-temps* (logand *available-backend-imm-temps* (lognot (logior ,@(mapcar #'(lambda (r) `(ash 1 (hard-regspec-value ,r))) reserved)))))
368          ,@(mapcar #'(lambda (v) (let* ((var (if (atom v) v (car v)))
369                                         (mode-name (if (atom v) :u32 (cadr v)))) 
370                                    `(,var (select-imm-temp ',mode-name)))) immvars))
371          ,@body))
372
373
374(defmacro with-crf-target ((&rest reserved) name &body body)
375  `(let* ((,name (make-unwired-lreg 
376                  (available-crf-temp 
377                   (logand *available-backend-crf-temps* 
378                           (lognot (logior ,@(mapcar #'(lambda (r) `(ash 1 (ash (hard-regspec-value ,r) -2))) reserved))))))))
379     ,@body))
380
381(defmacro regspec-crf-gpr-case ((regspec regval) crf-form gpr-form)
382  (let* ((class (gensym)))
383    `(if ,regspec
384       (multiple-value-bind (,class ,regval) (regspec-class-and-value ,regspec hard-reg-class-gpr-crf-mask)
385         (declare (fixnum ,class))
386         (if (= ,class hard-reg-class-crf)
387           ,crf-form
388           ,gpr-form)))))
389
390;;; The NODE case may need to use ENSURING-NODE-TARGET.
391(defmacro unboxed-other-case ((regspec &rest mode-names)
392                              unboxed-case other-case)
393  `(if (and ,regspec
394        (= (hard-regspec-class ,regspec) hard-reg-class-gpr)
395        (logbitp  (get-regspec-mode ,regspec)
396         (logior ,@(mapcar #'(lambda (x) (ash 1 (gpr-mode-name-value x)))
397                           mode-names))))
398    ,unboxed-case
399    ,other-case))
400
401
402
403
404;;; Choose an immediate register (for targeting), but don't "reserve" it.
405(defmacro with-imm-target ((&rest reserved) spec &body body)
406  (let* ((name (if (atom spec) spec (car spec)))
407         (mode-name (if (atom spec) :natural (cadr spec))))
408    `(let* ((,name (make-unwired-lreg
409                    (available-imm-temp
410                     (logand
411                      *available-backend-imm-temps* 
412                      (lognot (logior ,@(mapcar
413                                         #'(lambda (r)
414                                             `(ash 1 (hard-regspec-value ,r)))
415                                         reserved))))
416                     ',mode-name))))
417       ,@body)))
418
419(defmacro with-node-target ((&rest reserved) name &body body)
420  `(let* ((,name (make-unwired-lreg
421                  (available-node-temp
422                   (logand
423                    *available-backend-node-temps* 
424                    (lognot (logior ,@(mapcar
425                                       #'(lambda (r)
426                                           `(ash 1 (hard-regspec-value ,r)))
427                                       reserved))))))))
428    ,@body))
429
430
431
432
433(defmacro with-fp-target ((&rest reserved) spec &body body)
434  (let* ((name (if (atom spec) spec (car spec)))
435         (mode-name (if (atom spec) :double-float (cadr spec))))
436    `(let* ((,name
437             (make-unwired-lreg
438              (available-fp-temp
439               (logand *available-backend-fp-temps*
440                       (lognot (logior
441                                ,@(mapcar
442                                   #'(lambda (r) 
443                                       `(ash 1 (hard-regspec-value ,r)))
444                                   reserved))))
445               ',mode-name))))
446       ,@body)))
447
448(defmacro ensuring-node-target ((target-var vreg-var) &body body)
449  `(let* ((*available-backend-node-temps* *available-backend-node-temps*)
450          (,target-var (ensure-node-target ,vreg-var)))
451    (declare (special *available-backend-node-temps*))
452    (macrolet ((<- (&whole call &rest args)
453                 (declare (ignore args))
454                 (error "Invalid use of <- inside ENSURING-NODE-TARGET: ~s" call))
455               (^ (&whole call &rest args)
456                 (declare (ignore args))
457                 (error "Invalid use of ^ inside ENSURING-NODE-TARGET: ~s" call)))
458      (progn
459        ,@body))
460    (<- ,target-var)))
461
462(defun acode-invert-condition-keyword (k)
463  (or 
464   (cdr (assq k '((:eq . :ne) (:ne . :eq) (:le . :gt) (:lt . :ge) (:ge . :lt) (:gt . :le))))
465   (error "Unknown condition: ~s" k)))
466
467(defun backend-arch-macroexpand (whole env)
468  (let* ((expander (arch::arch-macro-function
469                    (backend-target-arch-name *target-backend*)
470                    (car whole))))
471    (if expander
472      (funcall expander whole env)
473      (error "No arch-specific macro function for ~s in arch ~s"
474             (car whole) (backend-target-arch-name *target-backend*)))))
475
476(defmacro declare-arch-specific-macro (name)
477  `(progn
478    (setf (macro-function ',name) #'backend-arch-macroexpand)
479    ',name))
480
481(defun target-nil-value (&optional (backend *target-backend*))
482  (+ (arch::target-nil-value (backend-target-arch backend))
483     (backend-lowmem-bias backend)))
484
485(defun target-t-value (&optional (backend *target-backend*))
486  (let* ((arch (backend-target-arch backend)))
487    (+ (arch::target-nil-value arch)
488       (arch::target-t-offset arch)
489       (backend-lowmem-bias backend))))
490
491
492     
Note: See TracBrowser for help on using the repository browser.