source: branches/rme-fpe/level-0/l0-hash.lisp @ 15779

Last change on this file since 15779 was 13279, checked in by gb, 10 years ago

Lots of changes from "purify" branch, mostly involving:

  • new memory layout, to support x86 function purification, static cons
  • fasloader changes to load/save string constants faster

Fasl version, image version changed; new binaries for all platforms soon.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 88.2 KB
Line 
1;;;-*- Mode: Lisp; Package: CCL -*-
2;;;
3;;;   Copyright (C) 2009 Clozure Associates
4;;;   Copyright (C) 1994-2001 Digitool, Inc
5;;;   This file is part of Clozure CL. 
6;;;
7;;;   Clozure CL is licensed under the terms of the Lisp Lesser GNU Public
8;;;   License , known as the LLGPL and distributed with Clozure CL as the
9;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
10;;;   which is distributed with Clozure CL as the file "LGPL".  Where these
11;;;   conflict, the preamble takes precedence. 
12;;;
13;;;   Clozure CL is referenced in the preamble as the "LIBRARY."
14;;;
15;;;   The LLGPL is also available online at
16;;;   http://opensource.franz.com/preamble.html
17
18(in-package "CCL")
19
20;;;;;;;;;;;;;
21;;
22;; See hash.lisp for documentation
23
24
25(eval-when (:compile-toplevel :execute)
26  (require "HASHENV" "ccl:xdump;hashenv")
27  (require :number-case-macro)
28  (define-symbol-macro deleted-hash-key-marker (%slot-unbound-marker))
29  (define-symbol-macro free-hash-marker (%unbound-marker))
30  (define-symbol-macro rehashing-value-marker (%slot-unbound-marker))
31  (declaim (inline nhash.vector-size))
32  (declaim (inline mixup-hash-code))
33  (declaim (inline hash-table-p))
34  (declaim (inline %%eqhash))
35  (declaim (inline index->vector-index vector-index->index swap))
36  (declaim (inline %already-rehashed-p %set-already-rehashed-p))
37  (declaim (inline need-use-eql))
38  (declaim (inline %needs-rehashing-p))
39  (declaim (inline compute-hash-code))
40  (declaim (inline eq-hash-find eq-hash-find-for-put))
41  (declaim (inline read-lock-hash-table write-lock-hash-table  unlock-hash-table))
42  (declaim (inline %hash-symbol))
43  (declaim (inline hash-mod))
44  (declaim (inline set-hash-key-conditional set-hash-value-conditional))
45  (declaim (inline hash-lock-free-p lock-free-gethash)))
46
47
48
49(defun %cons-hash-table (keytrans-function compare-function vector
50                         threshold rehash-ratio rehash-size find find-new owner &optional lock-free-p)
51  (%istruct
52   'HASH-TABLE                          ; type
53   keytrans-function                    ; nhash.keytransF
54   compare-function                     ; nhash.compareF
55   nil                                  ; nhash.rehash-bits
56   vector                               ; nhash.vector
57   (if lock-free-p $nhash.lock-free 0)  ; nhash.lock
58   owner                                ; nhash.owner
59   threshold                            ; nhash.grow-threshold
60   rehash-ratio                         ; nhash.rehash-ratio
61   rehash-size                          ; nhash.rehash-size
62   0                                    ; nhash.puthash-count
63   (if lock-free-p
64     (make-lock)
65     (unless owner (make-read-write-lock))) ; nhash.exclusion-lock
66   find                                 ; nhash.find
67   find-new                             ; nhash.find-new
68   nil                                  ; nhash.read-only
69   ))
70
71(defun nhash.vector-size (vector)
72  (nhash.vector.size vector))
73
74(defun hash-mod (hash entries vector)
75  (fast-mod-3 hash entries (nhash.vector.size-reciprocal vector)))
76
77;; For lock-free hash tables
78(defun set-hash-key-conditional (index vector old new)
79  (%set-hash-table-vector-key-conditional (%i+ target::misc-data-offset
80                                               (ash (the fixnum index) target::word-shift))
81                                          vector
82                                          old
83                                          new))
84
85(defun set-hash-value-conditional (index vector old new)
86  (store-gvector-conditional (%i+ index 1) vector old new))
87
88(defun hash-lock-free-p (hash)
89  (logtest $nhash.lock-free (the fixnum (nhash.lock hash))))
90 
91;;; Is KEY something which can be EQL to something it's not EQ to ?
92;;; (e.g., is it a number or macptr ?)
93;;; This can be more general than necessary but shouldn't be less so.
94(defun need-use-eql (key)
95  (let* ((typecode (typecode key)))
96    (declare (fixnum typecode))
97    (or (= typecode target::subtag-macptr)
98        #+(or ppc32-target x8632-target)
99        (and (>= typecode target::min-numeric-subtag)
100             (<= typecode target::max-numeric-subtag))
101        #+64-bit-target
102        (or (= typecode target::subtag-bignum)
103            (= typecode target::subtag-double-float)
104            (= typecode target::subtag-ratio)
105            (= typecode target::subtag-complex)))))
106
107;;; Don't rehash at all, unless some key is address-based (directly or
108;;; indirectly.)
109(defun %needs-rehashing-p (vector)
110  (let* ((flags (nhash.vector.flags vector)))
111    (declare (fixnum flags))
112    (if (logbitp $nhash_track_keys_bit flags)
113      ;; GC is tracking key movement
114      (logbitp $nhash_key_moved_bit flags)
115      ;; GC is not tracking key movement
116      (if (logbitp $nhash_component_address_bit flags)
117        (not (eql (the fixnum (%get-gc-count)) (the fixnum (nhash.vector.gc-count vector))))))))
118
119(defun %set-does-not-need-rehashing (vector)
120  (let* ((flags (nhash.vector.flags vector)))
121    (declare (fixnum flags))
122    (setf (nhash.vector.gc-count vector) (%get-gc-count))
123    (when (logbitp $nhash_track_keys_bit flags)
124      (setf (nhash.vector.flags vector)
125            (logand (lognot (ash 1 $nhash_key_moved_bit)) flags)))))
126
127
128;;; Tempting though it may be to remove this, a hash table loaded from
129;;; a fasl file likely needs to be rehashed, and the MAKE-LOAD-FORM
130;;; for hash tables needs to be able to call this or something similar.
131(defun %set-needs-rehashing (hash)
132  (let* ((vector (nhash.vector hash))
133         (flags (nhash.vector.flags vector)))
134    (declare (fixnum flags))
135    (setf (nhash.vector.gc-count vector) (the fixnum (1- (the fixnum (%get-gc-count)))))
136    (when (logbitp $nhash_track_keys_bit flags)
137      (setf (nhash.vector.flags vector) (logior (ash 1 $nhash_key_moved_bit) flags)))))
138
139#+32-bit-target
140(defun mixup-hash-code (fixnum)
141  (declare (fixnum fixnum))
142  (the fixnum
143    (+ fixnum
144       (the fixnum (%ilsl (- 32 8)
145                          (logand (1- (ash 1 (- 8 3))) fixnum))))))
146
147#+64-bit-target
148(defun mixup-hash-code (fixnum)
149  (declare (fixnum fixnum))
150  (the fixnum
151    (+ fixnum
152       (the fixnum (%ilsl 50
153                          (logand (1- (ash 1 (- 8 3))) fixnum))))))
154
155
156(defun rotate-hash-code (fixnum)
157  (declare (fixnum fixnum))
158  (let* ((low-3 (logand 7 fixnum))
159         (but-low-3 (%ilsr 3 fixnum))
160         (low-3*64K (%ilsl 13 low-3))
161         (low-3-in-high-3 (%ilsl (- 32 3 3) low-3)))
162    (declare (fixnum low-3 but-low-3 low-3*64K low-3-in-high-3))
163    (the fixnum (+ low-3-in-high-3
164                   (the fixnum (logxor low-3*64K but-low-3))))))
165
166
167
168
169(defconstant $nhash-track-keys-mask
170  #.(- (ash 1 $nhash_track_keys_bit)))
171
172(defconstant $nhash-clear-key-bits-mask #xfffff)
173
174
175(defun %hash-symbol (sym)
176  (if sym   
177    (let* ((vector (%symptr->symvector sym))
178           (cell (%svref vector target::symbol.plist-cell))
179           (consp (consp cell)))
180      (or (if consp (%car cell) cell)
181          (let* ((pname (%svref vector target::symbol.pname-cell))
182                 (hash (mixup-hash-code (%pname-hash pname (uvsize pname)))))
183            (declare (type simple-string pname) (fixnum hash))
184            (if consp
185              (setf (%car cell) hash)
186              (setf (%svref vector target::symbol.plist-cell) hash)))))
187    +nil-hash+))
188             
189;;; Hash on address, or at least on some persistent, immutable
190;;; attribute of the key.  If all keys are fixnums or immediates (or if
191;;; that attribute exists), rehashing won't ever be necessary.
192(defun %%eqhash (key)
193  (let* ((typecode (typecode key)))
194    (if (eq typecode target::tag-fixnum)
195      (values (mixup-hash-code key) nil)
196      (if (eq typecode target::subtag-instance)
197        (values (mixup-hash-code (instance.hash key)) nil)
198        (if (symbolp key)
199          (values (%hash-symbol key) nil)
200          (let ((hash (mixup-hash-code (strip-tag-to-fixnum key))))
201            (if (immediate-p-macro key)
202              (values hash nil)
203              (values hash :key ))))))))
204
205
206#+32-bit-target
207(defun swap (num)
208  (declare (fixnum num))
209  (the fixnum (+ (the fixnum (%ilsl 16 num))(the fixnum (%ilsr 13 num)))))
210
211#+64-bit-target
212(defun swap (num)
213  (declare (fixnum num))
214  (the fixnum (+ (the fixnum (%ilsl 32 num))(the fixnum (%ilsr 29 num)))))
215
216;;; teeny bit faster when nothing to do
217(defun %%eqlhash-internal (key)
218  (number-case key
219    (fixnum (mixup-hash-code key)) ; added this
220    (double-float (%dfloat-hash key))
221    (short-float (%sfloat-hash key))
222    (bignum (%bignum-hash key))
223    (ratio (logxor (swap (%%eqlhash-internal (numerator key)))
224                   (%%eqlhash-internal (denominator key))))
225    (complex
226     (logxor (swap (%%eqlhash-internal (realpart key)))
227             (%%eqlhash-internal (imagpart key))))
228    (t (cond ((macptrp key)
229              (%macptr-hash key))
230             (t key)))))
231
232               
233
234
235;;; new function
236
237(defun %%eqlhash (key)
238  ;; if key is a macptr, float, bignum, ratio, or complex, convert it
239  ;; to a fixnum
240  (if (hashed-by-identity key)
241    (%%eqhash key)
242    (let ((primary  (%%eqlhash-internal key)))
243      (if (eq primary key)
244        (%%eqhash key)
245        (mixup-hash-code (strip-tag-to-fixnum primary))))))
246
247
248(defun %%equalhash (key)
249  (let* ((id-p (hashed-by-identity key))
250         (hash (if (and key (not id-p)) (%%eqlhash-internal key)))
251         addressp)
252    (cond ((null key) (mixup-hash-code 17))
253          #+64-bit-target
254          ((and (typep key 'single-float)
255                (zerop (the single-float key)))
256           0)
257          ((immediate-p-macro key) (mixup-hash-code (strip-tag-to-fixnum key)))
258          ((and hash (neq hash key)) hash)  ; eql stuff
259          (t (typecase key
260                (simple-string (%pname-hash key (length key)))
261                (string
262                 (let ((length (length key)))
263                   (multiple-value-bind (data offset) (array-data-and-offset key)
264                     (%string-hash offset data length))))
265                (bit-vector (bit-vector-hash key))
266                (cons
267                 (let ((hash 0))
268                   (do* ((i 0 (1+ i))
269                         (list key (cdr list)))
270                        ((or (not (consp list)) (> i 11))) ; who figured 11?
271                     (declare (fixnum i))
272                     (multiple-value-bind (h1 a1) (%%equalhash (%car list))
273                       (when a1 (setq addressp t))
274                       ; fix the case of lists of same stuff in different order
275                       ;(setq hash (%ilogxor (fixnum-rotate h1 i) hash))
276                       (setq hash (%i+ (rotate-hash-code hash) h1))
277                       ))
278                   (values hash addressp)))
279                (pathname (%%equalphash key))
280                (t (%%eqlhash key)))))))
281
282(defun update-hash-flags (hash vector addressp)
283  (when addressp
284    (flet ((new-flags (flags addressp)
285             (declare (fixnum flags))
286             (if (eq :key addressp)
287               ;; hash code depended on key's address
288               (if (logbitp $nhash_component_address_bit flags)
289                 flags
290                 (logior $nhash-track-keys-mask
291                         (if (logbitp $nhash_track_keys_bit flags)
292                           flags
293                           (bitclr $nhash_key_moved_bit flags))))
294               ;; hash code depended on component address
295               (bitset $nhash_component_address_bit
296                       (logand (lognot $nhash-track-keys-mask) flags)))))
297      (declare (inline new-flags))
298      (if (hash-lock-free-p hash)
299        (loop
300          (let* ((flags (nhash.vector.flags vector))
301                 (new-flags (new-flags flags addressp)))
302            (when (or (eq flags new-flags)
303                      (store-gvector-conditional nhash.vector.flags vector flags new-flags))
304              (return))))
305        (setf (nhash.vector.flags vector)
306              (new-flags (nhash.vector.flags vector) addressp))))))
307
308(defun compute-hash-code (hash key update-hash-flags &optional
309                               (vector (nhash.vector hash))) ; vectorp))
310  (let ((keytransF (nhash.keytransF hash))
311        primary addressp)
312    (if (not (fixnump keytransF))
313      ;; not EQ or EQL hash table
314      (progn
315        (multiple-value-setq (primary addressp) (funcall keytransF key))
316        (let ((immediate-p (immediate-p-macro primary)))
317          (setq primary (strip-tag-to-fixnum primary))
318          (unless immediate-p
319            (setq primary (mixup-hash-code primary))
320            (setq addressp :key))))
321      ;; EQ or EQL hash table
322      (if (and (not (eql keytransF 0))
323               (need-use-eql key))
324        ;; EQL hash table
325        (setq primary (%%eqlhash-internal key))
326        ;; EQ hash table - or something eql doesn't do
327        (multiple-value-setq (primary addressp) (%%eqhash key))))
328    (when update-hash-flags
329      (when addressp
330        (update-hash-flags hash vector addressp)))
331    (let* ((entries (nhash.vector-size vector)))
332      (declare (fixnum entries))
333      (values primary
334              (hash-mod primary entries vector)
335              entries))))
336
337(defun %already-rehashed-p (primary rehash-bits)
338  (declare (optimize (speed 3)(safety 0)))
339  (declare (type (simple-array bit (*)) rehash-bits))
340  (eql 1 (sbit rehash-bits primary)))
341
342(defun %set-already-rehashed-p (primary rehash-bits)
343  (declare (optimize (speed 3)(safety 0)))
344  (declare (type (simple-array bit (*)) rehash-bits))
345  (setf (sbit rehash-bits primary) 1))
346
347
348(defun hash-table-p (hash)
349  (istruct-typep hash 'hash-table))
350
351(defun %normalize-hash-table-count (hash)
352  (let* ((vector (nhash.vector hash))
353         (weak-deletions-count (nhash.vector.weak-deletions-count vector)))
354    (declare (fixnum weak-deletions-count))
355    (unless (eql 0 weak-deletions-count)
356      (setf (nhash.vector.weak-deletions-count vector) 0)
357      ;; lock-free hash tables don't maintain deleted-count, since would need to
358      ;; lock and it's not worth it.
359      (unless (hash-lock-free-p hash)
360        (let ((deleted-count (the fixnum
361                               (+ (the fixnum (nhash.vector.deleted-count vector))
362                                  weak-deletions-count)))
363              (count (the fixnum (- (the fixnum (nhash.vector.count vector)) weak-deletions-count))))
364          (setf (nhash.vector.deleted-count vector) deleted-count
365                (nhash.vector.count vector) count))))))
366
367
368(defparameter *shared-hash-table-default* t
369  "Be sure that you understand the implications of changing this
370before doing so.")
371
372(defparameter *lock-free-hash-table-default* :shared
373  "If NIL, hash tables default to using the standard algorithms, with locks for shared tables.
374   If :SHARED, shared hash tables default to using the \"lock-free\" algorithm,
375   which is faster for typical access but slower for rehashing or growing the table.
376   Otherwise, all hash tables default to the lock-free algorithm")
377
378(defun make-hash-table (&key (test 'eql)
379                             (size 60)
380                             (rehash-size 1.5)
381                             (rehash-threshold .85)
382                             (hash-function nil)
383                             (weak nil)
384                             (finalizeable nil)
385                             (address-based t)  ;; Ignored
386                             (lock-free *lock-free-hash-table-default*)
387                             (shared *shared-hash-table-default*))
388  "Create and return a new hash table. The keywords are as follows:
389     :TEST -- Indicates what kind of test to use.
390     :SIZE -- A hint as to how many elements will be put in this hash
391       table.
392     :REHASH-SIZE -- Indicates how to expand the table when it fills up.
393       If an integer, add space for that many elements. If a floating
394       point number (which must be greater than 1.0), multiply the size
395       by that amount.
396     :REHASH-THRESHOLD -- Indicates how dense the table can become before
397       forcing a rehash. Can be any positive number <=1, with density
398       approaching zero as the threshold approaches 0. Density 1 means an
399       average of one entry per bucket."
400  (declare (ignore address-based)) ;; TODO: could reinterpret as "warn if becomes address-based"
401  (unless (and test (or (functionp test) (symbolp test)))
402    (report-bad-arg test '(and (not null) (or symbol function))))
403  (unless (or (functionp hash-function) (symbolp hash-function))
404    (report-bad-arg hash-function '(or symbol function)))
405  (unless (and (realp rehash-threshold) (<= 0.0 rehash-threshold) (<= rehash-threshold 1.0))
406    (report-bad-arg rehash-threshold '(real 0 1)))
407  (unless (or (fixnump rehash-size) (and (realp rehash-size) (< 1.0 rehash-size)))
408    (report-bad-arg rehash-size '(or fixnum (real 1 *))))
409  (unless (fixnump size) (report-bad-arg size 'fixnum))
410  (setq rehash-threshold (/ 1.0 (max 0.01 rehash-threshold)))
411  (let* ((default-hash-function
412             (cond ((or (eq test 'eq) (eq test #'eq)) 
413                    (setq test 0))
414                   ((or (eq test 'eql) (eq test #'eql)) 
415                    (setq test -1))
416                   ((or (eq test 'equal) (eq test #'equal))
417                    (setq test #'equal) #'%%equalhash)
418                   ((or (eq test 'equalp) (eq test #'equalp))
419                    (setq test #'equalp) #'%%equalphash)
420                   (t (setq test (require-type test 'symbol))
421                      (or hash-function 
422                          (error "non-standard test specified without hash-function")))))
423         (find-function
424          (case test
425            (0 #'eq-hash-find)
426            (-1 #'eql-hash-find)
427            (t #'general-hash-find)))
428         (find-put-function
429          (case test
430            (0 #'eq-hash-find-for-put)
431            (-1 #'eql-hash-find-for-put)
432            (t #'general-hash-find-for-put))))
433    (setq hash-function
434          (if hash-function
435            (require-type hash-function 'symbol)
436            default-hash-function))
437    (when (and weak (neq weak :value) (neq test 0))
438      (error "Only EQ hash tables can be weak."))
439    (when (and finalizeable (not weak))
440      (error "Only weak hash tables can be finalizeable."))
441    (when (and (eq lock-free :shared) (not shared))
442      (setq lock-free nil))
443    (multiple-value-bind (grow-threshold total-size)
444        (compute-hash-size (1- size) 1 rehash-threshold)
445      (let* ((flags (+ (if weak (ash 1 $nhash_weak_bit) 0)
446                       (ecase weak
447                         ((t nil :key) 0)
448                         (:value (ash 1 $nhash_weak_value_bit)))
449                       (if finalizeable (ash 1 $nhash_finalizeable_bit) 0)
450                       (if lock-free (ash 1 $nhash_keys_frozen_bit) 0)))
451             (hash (%cons-hash-table 
452                    hash-function test
453                    (%cons-nhash-vector total-size flags)
454                    grow-threshold rehash-threshold rehash-size
455                    find-function find-put-function
456                    (unless shared *current-process*)
457                    lock-free)))
458        (setf (nhash.vector.hash (nhash.vector hash)) hash)
459        hash))))
460
461(defun compute-hash-size (size rehash-size rehash-ratio)
462  (let* ((new-size size))
463    (declare (fixnum size new-size))
464    (setq new-size (max 30 (if (fixnump rehash-size)
465                             (%i+ size rehash-size)
466                             (ceiling (* size rehash-size)))))
467    (if (<= new-size size)
468      (setq new-size (1+ size)))        ; God save you if you make this happen
469   
470    (let ((vector-size (%hash-size (max (+ new-size 2) (ceiling (* new-size rehash-ratio))))))
471      ; TODO: perhaps allow more entries, based on actual size:
472      ;  (values (min (floor vector-size rehash-ratio) (%i- vector-size 2)) vector-size))
473      (values new-size vector-size)
474      )))
475
476;;;  Suggested size is a fixnum: number of pairs.  Return a fixnum >=
477;;;  that size that is relatively prime to all secondary keys.
478(defun %hash-size (suggestion)
479  (declare (fixnum suggestion))
480  (declare (optimize (speed 3)(safety 0)))
481  (if (<= suggestion #.(aref secondary-keys 7))
482    (setq suggestion (+ 2 #.(aref secondary-keys 7)))
483     (setq suggestion (logior 1 suggestion)))
484  (loop
485    (dovector (key secondary-keys (return-from %hash-size suggestion))
486      (when (eql 0 (fast-mod suggestion key))
487        (return)))
488    (incf suggestion 2)))
489
490
491(defvar *continue-from-readonly-hashtable-lock-error* t)
492
493(defun signal-read-only-hash-table-error (hash)
494  (cond ((hash-lock-free-p hash)
495         ;; We don't really do anything different if this is set, so no problem
496         (cerror "Modify it anyway"
497                 "Attempt to modify readonly hash table ~s" hash))
498        (*continue-from-readonly-hashtable-lock-error*
499         (cerror "Make the hash-table writable. DANGEROUS! This could damage your lisp if another thread is acccessing this table. CONTINUE ONLY IF YOU KNOW WHAT YOU'RE DOING!"
500                 "Hash-table ~s is readonly" hash)
501         (assert-hash-table-writeable hash)
502         (write-lock-hash-table hash))
503        (t (error "Hash-table ~s is readonly" hash))))
504
505(defun read-lock-hash-table (hash)
506  (if (nhash.read-only hash)
507    :readonly
508    (let* ((lock (nhash.exclusion-lock hash)))
509      (if lock
510        (read-lock-rwlock lock)
511        (unless (eq (nhash.owner hash) *current-process*)
512          (error "Not owner of hash table ~s" hash))))))
513
514(defun write-lock-hash-table (hash)
515  (if (nhash.read-only hash)
516    (signal-read-only-hash-table-error hash)
517    (let* ((lock (nhash.exclusion-lock hash)))
518      (if lock
519        (write-lock-rwlock lock)
520        (unless (eq (nhash.owner hash) *current-process*)
521          (error "Not owner of hash table ~s" hash))))))
522
523
524(defun unlock-hash-table (hash was-readonly)
525  (unless was-readonly
526    (let* ((lock (nhash.exclusion-lock hash)))
527      (if lock
528        (unlock-rwlock lock)))))
529
530(defun index->vector-index (index)
531  (declare (fixnum index))
532  (the fixnum (+ $nhash.vector_overhead (the fixnum (+ index index)))))
533
534(defun vector-index->index (index)
535  (declare (fixnum index))
536  (the fixnum (ash (the fixnum (- index $nhash.vector_overhead)) -1)))
537
538(defun hash-table-count (hash)
539  "Return the number of entries in the given HASH-TABLE."
540  (setq hash (require-type hash 'hash-table))
541  (when (hash-lock-free-p hash)
542    ;; We don't try to maintain a running total, so just count.
543    (return-from hash-table-count (lock-free-count-entries hash)))
544  (%normalize-hash-table-count hash)
545  (the fixnum (nhash.vector.count (nhash.vector hash))))
546
547(defun hash-table-rehash-size (hash)
548  "Return the rehash-size HASH-TABLE was created with."
549  (nhash.rehash-size (require-type hash 'hash-table)))
550
551(defun hash-table-rehash-threshold (hash)
552  "Return the rehash-threshold HASH-TABLE was created with."
553  (/ 1.0 (nhash.rehash-ratio (require-type hash 'hash-table))))
554
555(defun hash-table-size (hash)
556  "Return a size that can be used with MAKE-HASH-TABLE to create a hash
557   table that can hold however many entries HASH-TABLE can hold without
558   having to be grown."
559  (let* ((hash (require-type hash 'hash-table))
560         (vector (nhash.vector hash)))
561    (values (floor (nhash.vector.size vector) (nhash.rehash-ratio hash)))))
562
563(defun hash-table-test (hash)
564  "Return the test HASH-TABLE was created with."
565  (let ((f (nhash.compareF (require-type hash 'hash-table))))
566    (if (fixnump f)
567      (if (eql 0 f) 'eq 'eql)
568      (let ((name (if (symbolp f) f (function-name f))))
569        (if (memq name '(equal equalp)) name f)))))
570
571;;; sometimes you'd rather have the function than the symbol.
572(defun hash-table-test-function (hash)
573  (let ((f (nhash.compareF (require-type hash 'hash-table))))
574    (if (fixnump f)
575      (if (eql 0 f) #'eq #'eql)
576      f)))
577
578;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
579;;
580;; nearly-lock-free hash tables
581;;
582;; A modification of the lock-free hash table algorithm described by Cliff Click Jr.  in
583;; http://blogs.azulsystems.com/cliff/2007/03/a_nonblocking_h.html.
584;;
585;; The modifications have to do with the fact that our goal is just to minimize the
586;; performance impact of thread-safety, by eliminating the need for locking on every
587;; read.  I don't bother with aspects of his algorithm that aren't relevant to that goal.
588;;
589;; The main difference from Click's algorithm is that I don't try to do rehashing
590;; concurrently.  Instead, rehashing grabs a lock, so that only one thread can be
591;; rehashing at any given time, and readers/writers will block waiting for the rehashing
592;; to finish.
593;;
594;; In addition, I don't have a separate state for partially inserted key, I reuse the
595;; DELETED state for that.  So in our implementation the following are the possible states
596;; of a hash table entry (where "object" means any object other than the special markers):
597;;
598;; State      Key               Value
599;; DELETED1   object            free-hash-marker
600;; DELETED2   deleted-marker    free-hash-marker
601;; IN-USE     object            object
602;; FREE       free-hash-marker  free-hash-marker
603;; REHASHING  object            rehashing-value-marker
604;; REHASHING  free-hash-marker  rehashing-value-marker
605;; REHASHING  deleted-marker    rehashing-value-marker
606;;
607;; No other states are allowed - at no point in time can a hash table entry be in any
608;; other state.   In addition, the only transitions allowed on the key slot are
609;; free-hash-marker -> object/deleted-marker -> deleted-marker.  Once a key slot
610;; is claimed, it must never change to free or another key value (even after the hash
611;; vector has been discarded after rehashing, because there some process might still
612;; be looking at it).
613;; In particular, rehashing in place is not an option.  All rehashing creates a new
614;; vector and copies into it.  This means it's kinda risky to use lock-free hash
615;; tables with address-based keys, because they will thrash in low-memory situations,
616;; but we don't disallow it because a particular use might not have this problem.
617;;
618;; The following operations may take place:
619;;
620;; * gethash: find matching key - if no match, return not found.  Else fetch value,
621;;   if value is rehashing-value-marker then maybe-rehash and try again;
622;;   if value is free-hash-marker, return not found, else return found value.
623;;
624;; * puthash: find matching key or FREE slot.
625;;   ** If found key, fetch value.
626;;      if value is rehashing-value-marker then maybe-rehash and try again;
627;;      else store-conditional the value -> new value, if fails try again.
628;;   ** Else have FREE slot, store-key-conditional free-hash-marker -> key,
629;;      and if that succeeds, store-conditional free-hash-marker -> new value,
630;;      if either fails, maybe-rehash and try again.
631;;
632;; * remhash: find matching key - if no match, done.  Else fetch value,
633;;   if value is rehashing-value-marker then maybe-rehash and try again;
634;;   else store-conditional the value -> free-hash-marker, if fails try again.
635;;
636;; * rehash: grab a lock, estimate number of entries, make a new vector.  loop over
637;; old vector, at each entry fetch the old value with atomic swap of
638;; rehashing-value-marker.  This prevents any further state changes involving the
639;; value.  It doesn't prevent state changes involving the key, but the only ones that
640;; can happen is FREE -> DELETED, and DELETED1 <-> DELETED2, all of which are
641;; equivalent from the point of view of rehashing.  Anyway, if the old value was
642;; rehashing-value-marker then bug (because we have a lock).  If the old value is
643;; free-hash-marker then do nothing, else get the entry key and rehash into the new
644;; vector -- if no more room, start over.  When done, store the new vector in the
645;; hash table and release lock.
646;;
647;; * gc: for weak tables, gc may convert IN-USE states to DELETED2 states.
648;;   Even for non-weak tables, gc could convert DELETED1 states to DELETED2.
649
650
651(defun lock-free-rehash (hash)
652  ;;(break "We think we need to rehash ~s" (nhash.vector hash))
653  (with-lock-context
654    (without-interrupts ;; not re-entrant
655      (let ((lock (nhash.exclusion-lock hash)))
656        (%lock-recursive-lock-object lock)
657        ;; TODO: might also want to rehash if deleted entries are a large percentage
658        ;; of all entries, more or less.
659        (when (or (%i<= (nhash.grow-threshold hash) 0) ;; no room
660                  (%needs-rehashing-p (nhash.vector hash))) ;; or keys moved
661          (%lock-free-rehash hash))
662        (%unlock-recursive-lock-object lock)))))
663
664
665;; TODO: This is silly.  We're implementing atomic swap using store-conditional,
666;; but internally store-conditional is probably implemented using some kind of
667;; an atomic swap!!
668(defun atomic-swap-gvector (index gvector value)
669  (loop
670    (let ((old-value (%svref gvector index)))
671      (when (store-gvector-conditional index gvector old-value value)
672        (return old-value)))))
673
674;; Interrupts are disabled and caller has the hash lock on the table, blocking other
675;; threads attempting a rehash.
676;; Other threads might be reading/writing/deleting individual entries, but they
677;; will block if they see a value = rehashing-value-marker.
678;; GC may run, updating the needs-rehashing flags and deleting weak entries in both
679;; old and new vectors.
680(defun %lock-free-rehash (hash)
681  (let* ((old-vector (nhash.vector hash))
682         (inherited-flags (logand $nhash_weak_flags_mask (nhash.vector.flags old-vector)))
683         (grow-threshold (nhash.grow-threshold hash))
684         count new-vector vector-size)
685    ;; Prevent puthash from adding new entries.  Note this doesn't keep it from undeleting
686    ;; existing entries, so we might still lose, but this makes the odds much smaller.
687    (setf (nhash.grow-threshold hash) 0)
688    (setq count (lock-free-count-entries hash))
689    (multiple-value-setq (grow-threshold vector-size)
690      (if (%i<= grow-threshold 0) ; if ran out of room, grow, else get just enough.
691        (compute-hash-size count (nhash.rehash-size hash) (nhash.rehash-ratio hash))
692        (compute-hash-size count 1 (nhash.rehash-ratio hash))))
693    (setq new-vector (%cons-nhash-vector vector-size inherited-flags))
694    (loop with full-count = grow-threshold
695          for i from $nhash.vector_overhead below (uvsize old-vector) by 2
696          do (let* ((value (atomic-swap-gvector (%i+ i 1) old-vector rehashing-value-marker))
697                    (key (%svref old-vector i)))
698               (when (eq value rehashing-value-marker) (error "Who else is doing this?"))
699               (unless (or (eq value free-hash-marker) (eq key deleted-hash-key-marker))
700                 (let* ((new-index (%growhash-probe new-vector hash key))
701                        (new-vector-index (index->vector-index new-index)))
702                   (%set-hash-table-vector-key new-vector new-vector-index key)
703                   (setf (%svref new-vector (%i+ new-vector-index 1)) value)
704                   (decf grow-threshold)
705                   (when (%i<= grow-threshold 0)
706                     ;; Too many entries got undeleted while we were rehashing (that's the
707                     ;; only way we could end up with more than COUNT entries, as adding
708                     ;; new entries is blocked).  Grow the output vector.
709                     (multiple-value-bind (bigger-threshold bigger-vector-size)
710                         (compute-hash-size full-count (nhash.rehash-size hash) (nhash.rehash-ratio hash))
711                       (assert (> bigger-vector-size vector-size))
712                       (let ((bigger-vector (%cons-nhash-vector bigger-vector-size 0)))
713                         (%copy-gvector-to-gvector new-vector
714                                                   $nhash.vector_overhead
715                                                   bigger-vector
716                                                   $nhash.vector_overhead
717                                                   (%i- (uvsize new-vector) $nhash.vector_overhead))
718                         (setf (nhash.vector.flags bigger-vector) (nhash.vector.flags new-vector))
719                         (%lock-free-rehash-in-place hash bigger-vector)
720                         (setq grow-threshold (- bigger-threshold full-count))
721                         (setq full-count bigger-threshold)
722                         (setq new-vector bigger-vector)
723                         (setq vector-size bigger-vector-size))))))))
724    (when (%needs-rehashing-p new-vector) ;; keys moved, but at least can use the same new-vector.
725      (%lock-free-rehash-in-place hash new-vector))
726    (setf (nhash.vector.hash new-vector) hash)
727    (setf (nhash.grow-threshold hash) grow-threshold)
728    ;; At this point, another thread might decrement the threshold while they're looking at the old
729    ;; vector. That's ok, just means it will be too small and we'll rehash sooner than planned,
730    ;; no big deal.
731    (setf (nhash.vector hash) new-vector)))
732
733;; This is called on a new vector that hasn't been installed yet, so no other thread is
734;; accessing it.  However, gc might be deleting stuff from it, which is why it tests
735;; key for deleted-hash-key-marker in addition to free-hash-marker value
736(defun %lock-free-rehash-in-place (hash vector)
737  (let* ((vector-index (- $nhash.vector_overhead 2))
738         (size (nhash.vector-size vector))
739         (rehash-bits (%make-rehash-bits hash size))
740         (index -1))
741    (declare (fixnum size index vector-index))
742    (%set-does-not-need-rehashing vector)
743    (loop
744      (when (>= (incf index) size) (return))
745      (setq vector-index (+ vector-index 2))
746      (unless (%already-rehashed-p index rehash-bits)
747        (let* ((value (%svref vector (%i+ vector-index 1)))
748               (key (%svref vector vector-index)))
749          (if (or (eq value free-hash-marker)
750                  (eq key deleted-hash-key-marker))
751            (unless (eq key free-hash-marker)
752              (setf (%svref vector vector-index) free-hash-marker))
753            (let* ((last-index index)
754                   (first t))
755              (loop
756                (let ((found-index (%rehash-probe rehash-bits hash key vector)))
757                  (%set-already-rehashed-p found-index rehash-bits)
758                  (when (eq last-index found-index)
759                    (return))
760                  (let* ((found-vector-index (index->vector-index found-index))
761                         (newvalue (%svref vector (the fixnum (1+ found-vector-index))))
762                         (newkey (%svref vector found-vector-index)))
763                    (declare (fixnum found-vector-index))
764                    (when first         ; or (eq last-index index) ?
765                      (setq first nil)
766                      (setf (%svref vector (the fixnum (1+ vector-index))) free-hash-marker)
767                      (setf (%svref vector vector-index) free-hash-marker))
768                    (%set-hash-table-vector-key vector found-vector-index key)
769                    (setf (%svref vector (the fixnum (1+ found-vector-index))) value)
770                    (when (or (eq newkey deleted-hash-key-marker)
771                              (eq newvalue free-hash-marker))
772                      (return))
773                    (when (eq key newkey)
774                      (cerror "Delete one of the entries." "Duplicate key: ~s in ~s ~s ~s ~s ~s"
775                              key hash value newvalue index found-index)                       
776                      (return))
777                    (setq key newkey
778                          value newvalue
779                          last-index found-index))))))))))
780  t )
781
782
783(defun lock-free-gethash (key hash default)
784  (declare (optimize (speed 3) (safety 0) (debug 0)))
785  (loop
786    (let* ((vector (nhash.vector hash))
787           (vector-index (funcall (the function (nhash.find hash)) hash key)))
788      (declare (fixnum vector-index))
789      ;; Need to punt if vector changed because no way to know whether nhash.find was
790      ;; using old or new vector.
791      (when (eq vector (nhash.vector hash))
792        (cond ((eql vector-index -1)
793               (unless (%needs-rehashing-p vector)
794                 (return-from lock-free-gethash (values default nil))))
795              (t (let ((value (%svref vector (%i+ vector-index 1))))
796                   (unless (eq value rehashing-value-marker)
797                     (if (eq value free-hash-marker)
798                       (return-from lock-free-gethash (values default nil))
799                       (return-from lock-free-gethash (values value t)))))))))
800    ;; We're here because the table needs rehashing or it was getting rehashed while we
801    ;; were searching. Take care of it and try again.
802    (lock-free-rehash hash)))
803
804(defun lock-free-remhash (key hash)
805  (declare (optimize (speed 3) (safety 0) (debug 0)))
806  (when (nhash.read-only hash)
807    (signal-read-only-hash-table-error hash)) ;; continuable
808  (loop
809    (let* ((vector (nhash.vector hash))
810           (vector-index (funcall (the function (nhash.find hash)) hash key)))
811      (declare (fixnum vector-index))
812      ;; Need to punt if vector changed because no way to know whether nhash.find was
813      ;; using old or new vector.
814      (when (eq vector (nhash.vector hash))
815        (cond ((eql vector-index -1)
816               (unless (%needs-rehashing-p vector)
817                 (return-from lock-free-remhash nil)))
818              (t (let ((old-value (%svref vector (%i+ vector-index 1))))
819                   (unless (eq old-value rehashing-value-marker)
820                     (when (eq old-value free-hash-marker)
821                       (return-from lock-free-remhash nil))
822                     (when (set-hash-value-conditional vector-index vector old-value free-hash-marker)
823                       ;; We just use this as a flag - tell gc to scan the vector for deleted keys.
824                       ;; It's just a hint, so don't worry about sync'ing
825                       (setf (nhash.vector.deleted-count vector) 1)
826                       (return-from lock-free-remhash t)))))))
827      ;; We're here because the table needs rehashing or it was getting rehashed while we
828      ;; were searching.  Take care of it and try again.
829      (lock-free-rehash hash))))
830
831(defun lock-free-clrhash (hash)
832  (when (nhash.read-only hash)
833    (signal-read-only-hash-table-error hash)) ;;continuable
834  (with-lock-context
835    (without-interrupts
836     (let ((lock (nhash.exclusion-lock hash)))
837       (%lock-recursive-lock-object lock) ;; disallow rehashing.
838       (loop
839         with vector = (nhash.vector hash)
840         for i1 fixnum from (%i+ $nhash.vector_overhead 1) below (uvsize vector) by 2
841         do (setf (%svref vector i1) free-hash-marker)
842         ;; We just use this as a flag - tell gc to scan the vector for deleted keys.
843         ;; It's just a hint, so don't worry about sync'ing
844         finally (setf (nhash.vector.deleted-count vector) 1))
845       (%unlock-recursive-lock-object lock))))
846  hash)
847
848(defun lock-free-puthash (key hash value)
849  (declare (optimize (speed 3) (safety 0) (debug 0)))
850  (when (or (eq value rehashing-value-marker)
851            (eq value free-hash-marker))
852    (error "Illegal value ~s for storing in a hash table" value))
853  (when (nhash.read-only hash)
854    (signal-read-only-hash-table-error hash)) ;;continuable
855  (loop
856    (let* ((vector (nhash.vector  hash))
857           (vector-index (funcall (nhash.find-new hash) hash key)))
858      ;; Need to punt if vector changed because no way to know whether nhash.find-new was
859      ;; using old or new vector.
860      (when (eq vector (nhash.vector hash))
861        (cond ((or (eql vector-index -1)
862                   (eq (%svref vector vector-index) free-hash-marker))
863               (unless (or (%needs-rehashing-p vector)
864                           (%i<= (nhash.grow-threshold hash) 0))
865                 ;; Note if the puthash fails, grow-threshold will end up too small. This
866                 ;; just means we might rehash sooner than absolutely necessary, no real
867                 ;; harm done (the most likely cause of failing is that somebody is
868                 ;; already rehashing anyway).  DON'T try to incf it back on failure --
869                 ;; that risks grow-threshold ending up too big (e.g. if somebody rehashes
870                 ;; before the incf), which _could_ be harmful.
871                 (atomic-decf (nhash.grow-threshold hash))
872                 (if (set-hash-key-conditional vector-index vector free-hash-marker key)
873                   (when (set-hash-value-conditional vector-index vector free-hash-marker value)
874                     (return-from lock-free-puthash value)))))
875              (t (let ((old-value (%svref vector (%i+ vector-index 1))))
876                   (unless (eq old-value rehashing-value-marker)
877                     (when (set-hash-value-conditional vector-index vector old-value value)
878                       (return-from lock-free-puthash value))))))))
879    ;; We're here because the table needs rehashing or it was getting rehashed while we
880    ;; were searching, or no room for new entry, or somebody else claimed the key from
881    ;; under us (that last case doesn't need to retry, but it's unlikely enough that
882    ;; it's not worth checking for).  Take care of it and try again.
883    (lock-free-rehash hash)))
884
885(defun lock-free-count-entries (hash)
886  ;; Other threads could be adding/removing entries while we count, some of
887  ;; which will be included in the count (i.e. will be treated as if they
888  ;; happened after counting) and some won't (i.e. will be treated as if
889  ;; they happened before counting), but not necessarily in correlation
890  ;; with their temporal relationship.
891  (loop
892    with vector = (nhash.vector hash)
893    for i fixnum from $nhash.vector_overhead below (uvsize vector) by 2
894    count (let ((value (%svref vector (%i+ i 1))))
895            (when (eq value rehashing-value-marker)
896              ;; This table is being rehashed.  Wait for it to be
897              ;; done and try again.
898              (lock-free-rehash hash)
899              (return-from lock-free-count-entries (lock-free-count-entries hash)))
900            (neq value free-hash-marker))))
901
902;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
903
904
905(defun gethash (key hash &optional default)
906  "Finds the entry in HASH-TABLE whose key is KEY and returns the associated
907   value and T as multiple values, or returns DEFAULT and NIL if there is no
908   such entry. Entries can be added using SETF."
909  (unless (typep hash 'hash-table)
910    (report-bad-arg hash 'hash-table))
911  (when (or (eq key free-hash-marker)
912            (eq key deleted-hash-key-marker))
913    (return-from gethash (values default nil)))
914  (when (hash-lock-free-p hash)
915    (return-from gethash (lock-free-gethash key hash default)))
916  (let* ((value nil)
917         (gc-locked nil)
918         (readonly nil)
919         (foundp nil))
920    (with-lock-context
921      (without-interrupts
922        (setq readonly (eq (read-lock-hash-table hash) :readonly))
923        (let* ((vector (nhash.vector hash)))
924          (if (and (eq key (nhash.vector.cache-key vector))
925                   ;; Check twice: the GC might nuke the cached key/value pair
926                   (progn (setq value (nhash.vector.cache-value vector))
927                          (eq key (nhash.vector.cache-key vector))))
928            (setq foundp t)
929            (loop
930              (let* ((vector-index (funcall (nhash.find hash) hash key)))
931                (declare (fixnum vector-index))
932                (cond ((setq foundp (not (eql vector-index -1)))
933                       ;; Referencing both key and value here - and referencing
934                       ;; value first - is an attempt to compensate for the
935                       ;; possibility that the GC deletes a weak-on-key pair.
936                       (setq value (%svref vector (%i+ vector-index 1)))
937                       (when (nhash.owner hash)
938                         (setf (nhash.vector.cache-key vector)
939                               (%svref vector vector-index)
940                               (nhash.vector.cache-value vector)
941                               value
942                               (nhash.vector.cache-idx vector)
943                               (vector-index->index (the fixnum vector-index))))
944                       (return))
945                      ((%needs-rehashing-p vector)
946                       (%lock-gc-lock)
947                       (setq gc-locked t)
948                       (unless readonly
949                         (let* ((lock (nhash.exclusion-lock hash)))
950                           (when lock (%promote-rwlock lock))))
951                       (when (%needs-rehashing-p vector)
952                         (%rehash hash)))
953                      (t (return)))))))
954        (when gc-locked (%unlock-gc-lock))
955        (unlock-hash-table hash readonly)))
956    (if foundp
957      (values value t)
958      (values default nil))))
959
960(defun remhash (key hash)
961  "Remove the entry in HASH-TABLE associated with KEY. Return T if there
962   was such an entry, or NIL if not."
963  (unless (typep hash 'hash-table)
964    (setq hash (require-type hash 'hash-table)))
965  (when (hash-lock-free-p hash)
966    (return-from remhash (lock-free-remhash key hash)))
967  (let* ((foundp nil))
968    (with-lock-context
969      (without-interrupts
970       (write-lock-hash-table hash)
971       (%lock-gc-lock)
972       (let* ((vector (nhash.vector hash)))
973         (when (%needs-rehashing-p vector)
974           (%rehash hash))
975         (if (eq key (nhash.vector.cache-key vector))
976           (progn
977             (setf (nhash.vector.cache-key vector) free-hash-marker
978                   (nhash.vector.cache-value vector) nil)
979             (let ((vidx (index->vector-index (nhash.vector.cache-idx vector))))
980               (setf (%svref vector vidx) deleted-hash-key-marker)
981               (setf (%svref vector (the fixnum (1+ vidx))) nil))
982             (incf (the fixnum (nhash.vector.deleted-count vector)))
983             (decf (the fixnum (nhash.vector.count vector)))
984             (setq foundp t))
985           (let* ((vector-index (funcall (nhash.find hash) hash key)))
986             (declare (fixnum vector-index))
987             (unless (eql vector-index -1)
988               ;; always clear the cache cause I'm too lazy to call the
989               ;; comparison function and don't want to keep a possibly
990               ;; deleted key from being GC'd
991               (setf (nhash.vector.cache-key vector) free-hash-marker
992                     (nhash.vector.cache-value vector) nil)
993               ;; Update the count
994               (incf (the fixnum (nhash.vector.deleted-count vector)))
995               (decf (the fixnum (nhash.vector.count vector)))
996               ;; Delete the value from the table.
997               (setf (%svref vector vector-index) deleted-hash-key-marker
998                     (%svref vector (the fixnum (1+ vector-index))) nil)
999               (setq foundp t))))
1000         (when (and foundp
1001                    (zerop (the fixnum (nhash.vector.count vector))))
1002           (do* ((i $nhash.vector_overhead (1+ i))
1003                 (n (uvsize vector)))
1004                ((= i n))
1005             (declare (fixnum i n))
1006             (setf (%svref vector i) free-hash-marker))
1007           (setf (nhash.grow-threshold hash)
1008                 (+ (nhash.vector.deleted-count vector)
1009                    (nhash.vector.weak-deletions-count vector)
1010                    (nhash.grow-threshold hash))
1011                 (nhash.vector.deleted-count vector) 0
1012                 (nhash.vector.weak-deletions-count vector) 0)))
1013       ;; Return T if we deleted something
1014       (%unlock-gc-lock)
1015       (unlock-hash-table hash nil)))
1016    foundp))
1017
1018;;; what if somebody is mapping, growing, rehashing?
1019(defun clrhash (hash)
1020  "This removes all the entries from HASH-TABLE and returns the hash table
1021   itself."
1022  (unless (typep hash 'hash-table)
1023    (report-bad-arg hash 'hash-table))
1024  (when (hash-lock-free-p hash)
1025    (return-from clrhash (lock-free-clrhash hash)))
1026  (with-lock-context
1027    (without-interrupts
1028     (write-lock-hash-table hash)
1029     (let* ((vector (nhash.vector hash))
1030            (size (nhash.vector-size vector))
1031            (count (+ size size))
1032            (index $nhash.vector_overhead))
1033       (declare (fixnum size count index))
1034       (dotimes (i count)
1035         (setf (%svref vector index) free-hash-marker)
1036         (incf index))
1037       (incf (the fixnum (nhash.grow-threshold hash))
1038             (the fixnum (+ (the fixnum (nhash.vector.count vector))
1039                            (the fixnum (nhash.vector.deleted-count vector)))))
1040       (setf (nhash.vector.count vector) 0
1041             (nhash.vector.cache-key vector) free-hash-marker
1042             (nhash.vector.cache-value vector) nil
1043             (nhash.vector.finalization-alist vector) nil
1044             (nhash.vector.free-alist vector) nil
1045             (nhash.vector.weak-deletions-count vector) 0
1046             (nhash.vector.deleted-count vector) 0
1047             (nhash.vector.flags vector) (logand $nhash_weak_flags_mask
1048                                                 (nhash.vector.flags vector))))
1049     (unlock-hash-table hash nil)
1050     hash)))
1051
1052
1053(defun puthash (key hash default &optional (value default))
1054  (declare (optimize (speed 3) (space 0)))
1055  (unless (typep hash 'hash-table)
1056    (report-bad-arg hash 'hash-table))
1057  (when (or (eq key free-hash-marker)
1058            (eq key deleted-hash-key-marker))
1059    (error "Can't use ~s as a hash-table key" key))
1060  (when (hash-lock-free-p hash)
1061    (return-from puthash (lock-free-puthash key hash value)))
1062  (with-lock-context
1063    (without-interrupts
1064     (block protected
1065       (tagbody
1066          (write-lock-hash-table hash)
1067        AGAIN
1068          (%lock-gc-lock)
1069          (let ((vector (nhash.vector hash)))
1070            (when (%needs-rehashing-p vector)
1071              (%rehash hash))
1072            (when (eq key (nhash.vector.cache-key vector))
1073              (let* ((idx (nhash.vector.cache-idx vector)))
1074                (declare (fixnum idx))
1075                (setf (%svref vector (the fixnum (1+ (the fixnum (index->vector-index idx)))))
1076                      value)
1077                (setf (nhash.vector.cache-value vector) value)
1078                (return-from protected)))               
1079            (let* ((vector-index (funcall (nhash.find-new hash) hash key))
1080                   (old-value (%svref vector vector-index)))
1081              (declare (fixnum vector-index))
1082
1083              (cond ((eq old-value deleted-hash-key-marker)
1084                     (%set-hash-table-vector-key vector vector-index key)
1085                     (setf (%svref vector (the fixnum (1+ vector-index))) value)
1086                     (incf (the fixnum (nhash.vector.count vector)))
1087                     ;; Adjust deleted-count
1088                     (when (> 0 (the fixnum
1089                                  (decf (the fixnum
1090                                          (nhash.vector.deleted-count vector)))))
1091                       (%normalize-hash-table-count hash)))
1092                    ((eq old-value free-hash-marker)
1093                     (when (eql 0 (nhash.grow-threshold hash))
1094                       (%unlock-gc-lock)
1095                       (%grow-hash-table hash)
1096                       (go AGAIN))
1097                     (%set-hash-table-vector-key vector vector-index key)
1098                     (setf (%svref vector (the fixnum (1+ vector-index))) value)
1099                     (decf (the fixnum (nhash.grow-threshold hash)))
1100                     (incf (the fixnum (nhash.vector.count vector))))
1101                    (t
1102                     ;; Key was already there, update value.
1103                     (setf (%svref vector (the fixnum (1+ vector-index))) value)))
1104              (setf (nhash.vector.cache-idx vector) (vector-index->index vector-index)
1105                    (nhash.vector.cache-key vector) key
1106                    (nhash.vector.cache-value vector) value)))))
1107     (%unlock-gc-lock)
1108     (unlock-hash-table hash nil)))
1109  value)
1110
1111
1112(defun count-entries (hash)
1113  (if (hash-lock-free-p hash)
1114    (lock-free-count-entries hash)
1115    (let* ((vector (nhash.vector hash))
1116           (size (uvsize vector))
1117           (idx $nhash.vector_overhead)
1118           (count 0))
1119      (loop
1120        (when (neq (%svref vector idx) free-hash-marker)
1121          (incf count))
1122        (when (>= (setq idx (+ idx 2)) size)
1123          (return count))))))
1124
1125
1126
1127
1128
1129     
1130
1131(defun grow-hash-table (hash)
1132  (unless (typep hash 'hash-table)
1133    (setq hash (require-type hash 'hash-table)))
1134  (%grow-hash-table hash))
1135
1136;;; Interrupts are disabled, and the caller has an exclusive
1137;;; lock on the hash table.
1138(defun %grow-hash-table (hash)
1139  (block grow-hash-table
1140    (%normalize-hash-table-count hash)
1141    (let* ((old-vector (nhash.vector hash))
1142           (old-size (nhash.vector.count old-vector))
1143           (old-total-size (nhash.vector.size old-vector))
1144           (flags 0)
1145           (flags-sans-weak 0)
1146           (weak-flags nil))
1147      (declare (fixnum old-total-size flags flags-sans-weak))
1148      (when (> (nhash.vector.deleted-count old-vector) 0)
1149        ;; There are enough deleted entries. Rehash to get rid of them
1150        (%rehash hash)
1151        (return-from grow-hash-table))
1152      (multiple-value-bind (size total-size)
1153                           (compute-hash-size 
1154                            old-size (nhash.rehash-size hash) (nhash.rehash-ratio hash))
1155        (unless (eql 0 (nhash.grow-threshold hash))       ; maybe it's done already - shouldnt happen               
1156          (return-from grow-hash-table ))
1157        (progn
1158          (unwind-protect
1159            (let ((gc-count (%get-gc-count))
1160                  vector)
1161              (setq flags (nhash.vector.flags old-vector)
1162                    flags-sans-weak (logand flags (logxor -1 $nhash_weak_flags_mask))
1163                    weak-flags (logand flags $nhash_weak_flags_mask))
1164              (setf (nhash.vector.flags old-vector) flags-sans-weak)      ; disable GC weak stuff
1165              (%normalize-hash-table-count hash)
1166              (when (> (nhash.vector.deleted-count old-vector) 0)
1167                (setf (nhash.vector.flags old-vector) flags)
1168                (setq weak-flags nil)
1169                (return-from grow-hash-table (%rehash hash)))
1170              (setq vector (%cons-nhash-vector total-size 0))
1171              (do* ((index 0 (1+ index))
1172                    (vector-index (index->vector-index 0) (+ vector-index 2)))
1173                   ((>= index old-total-size))
1174                (declare (fixnum index vector-index))
1175               
1176                 (let ((key (%svref old-vector vector-index)))
1177                   (unless (or (eq key free-hash-marker)
1178                               (eq key deleted-hash-key-marker))
1179                     (let* ((new-index (%growhash-probe vector hash key))
1180                            (new-vector-index (index->vector-index new-index)))
1181                       (setf (%svref vector new-vector-index) key)
1182                       (setf (%svref vector (the fixnum (1+ new-vector-index)))
1183                             (%svref old-vector (the fixnum (1+ vector-index))))))))
1184              (progn
1185               (setf (nhash.vector.finalization-alist vector)
1186                     (nhash.vector.finalization-alist old-vector)
1187                     (nhash.vector.free-alist vector)
1188                     (nhash.vector.free-alist old-vector)
1189                     (nhash.vector.count vector) old-size
1190                     (nhash.vector.flags vector)
1191                     (logior (the fixnum weak-flags)
1192                             (the fixnum (nhash.vector.flags vector))))
1193               (setf (nhash.rehash-bits hash) nil
1194                     (nhash.vector hash) vector
1195                     (nhash.vector.hash vector) hash
1196                     (nhash.vector.cache-key vector) free-hash-marker
1197                     (nhash.vector.cache-value vector) nil
1198                     (nhash.vector.gc-count vector) gc-count
1199                     (nhash.grow-threshold hash) (- size old-size))
1200               (setq weak-flags nil)       ; tell clean-up form we finished the loop
1201               ;; If the old vector's in some static heap, zero it
1202               ;; so that less garbage is retained.
1203               (%init-misc 0 old-vector)))
1204            (when weak-flags
1205              (setf (nhash.vector.flags old-vector)
1206                    (logior (the fixnum weak-flags)
1207                            (the fixnum (nhash.vector.flags old-vector)))))))))))
1208
1209
1210
1211(defun general-hash-find (hash key)
1212  (%hash-probe hash key nil))
1213
1214(defun general-hash-find-for-put (hash key)
1215  (%hash-probe hash key (if (hash-lock-free-p hash) :free :reuse)))
1216
1217;;; returns a single value:
1218;;;   index - the index in the vector for key (where it was or where
1219;;;           to insert if the current key at that index is deleted-hash-key-marker
1220;;;           or free-hash-marker)
1221
1222
1223
1224(defun %hash-probe (hash key for-put-p)
1225  (declare (optimize (speed 3) (space 0)))
1226  (multiple-value-bind (hash-code index entries)
1227                       (compute-hash-code hash key for-put-p)
1228    (locally (declare (fixnum hash-code index entries))
1229      (let* ((compareF (nhash.compareF hash))
1230             (vector (nhash.vector hash))
1231             (vector-index 0)
1232             table-key
1233             (first-deleted-index nil))
1234        (declare (fixnum vector-index))
1235        (macrolet ((return-it (form)
1236                     `(return-from %hash-probe ,form)))
1237          (macrolet ((test-it (predicate)
1238                       (unless (listp predicate) (setq predicate (list predicate)))
1239                       `(progn
1240                          (setq vector-index (index->vector-index index)
1241                                table-key (%svref vector vector-index))
1242                          (cond ((eq table-key free-hash-marker)
1243                                 (return-it (if for-put-p
1244                                              (or first-deleted-index
1245                                                  vector-index)
1246                                              -1)))
1247                                ((eq table-key deleted-hash-key-marker)
1248                                 (when (and (eq for-put-p :reuse)
1249                                            (null first-deleted-index))
1250                                   (setq first-deleted-index vector-index)))
1251                                ((,@predicate key table-key)
1252                                 (return-it vector-index))))))
1253            (macrolet ((do-it (predicate)
1254                         `(progn
1255                            (test-it ,predicate)
1256                            ; First probe failed. Iterate on secondary key
1257                            (let ((initial-index index)
1258                                  (secondary-hash (%svref secondary-keys (logand 7 hash-code))))
1259                              (declare (fixnum secondary-hash initial-index))
1260                              (loop
1261                                (incf index secondary-hash)
1262                                (when (>= index entries)
1263                                  (decf index entries))
1264                                (when (eql index initial-index)
1265                                  (return-it (if for-put-p
1266                                               (or first-deleted-index
1267                                                   (error "Bug: no room in table"))
1268                                               -1)))
1269                                (test-it ,predicate))))))
1270              (if (fixnump comparef)
1271                ;; EQ or EQL hash table
1272                (if (or (eql 0 comparef)
1273                        (immediate-p-macro key)
1274                        (not (need-use-eql key)))
1275                  ;; EQ hash table or EQL == EQ for KEY
1276                  (do-it eq)
1277                  (do-it eql))
1278                ;; general compare function
1279                (do-it (funcall comparef))))))))))
1280
1281(defun eq-hash-find (hash key)
1282  (declare (optimize (speed 3) (safety 0)))
1283  (let* ((vector (nhash.vector hash))
1284         (hash-code
1285          (let* ((typecode (typecode key)))
1286            (if (eq typecode target::tag-fixnum)
1287              (mixup-hash-code key)
1288              (if (eq typecode target::subtag-instance)
1289                (mixup-hash-code (instance.hash key))
1290                (if (symbolp key)
1291                  (%hash-symbol key)
1292                  (mixup-hash-code (strip-tag-to-fixnum key)))))))
1293         (entries (nhash.vector-size vector))
1294         (vector-index (index->vector-index (hash-mod hash-code entries vector)))
1295         (table-key (%svref vector vector-index)))
1296    (declare (fixnum hash-code  entries vector-index))
1297    (if (eq table-key key)
1298      vector-index
1299      (if (eq table-key free-hash-marker)
1300        -1
1301        (let* ((secondary-hash (%svref secondary-keys-*-2
1302                                       (logand 7 hash-code)))
1303               (initial-index vector-index)             
1304               (count (+ entries entries))
1305               (length (+ count $nhash.vector_overhead)))
1306          (declare (fixnum secondary-hash initial-index count length))
1307          (loop
1308            (incf vector-index secondary-hash)
1309            (when (>= vector-index length)
1310              (decf vector-index count))
1311            (setq table-key (%svref vector vector-index))
1312            (when (= vector-index initial-index)
1313              (return -1))
1314            (if (eq table-key key)
1315              (return vector-index)
1316              (when (eq table-key free-hash-marker)
1317                (return -1)))))))))
1318
1319;;; As above, but note whether the key is in some way address-based
1320;;; and update the hash-vector's flags word if so.
1321;;; This only needs to be done by PUTHASH, and it only really needs
1322;;; to be done if we're adding a new key.
1323(defun eq-hash-find-for-put (hash key)
1324  (declare (optimize (speed 3) (safety 0)))
1325  (let* ((vector (nhash.vector hash))
1326         (hash-code
1327          (let* ((typecode (typecode key)))
1328            (if (eq typecode target::tag-fixnum)
1329              (mixup-hash-code key)
1330              (if (eq typecode target::subtag-instance)
1331                (mixup-hash-code (instance.hash key))
1332                (if (symbolp key)
1333                  (%hash-symbol key)
1334                  (progn
1335                    (unless (immediate-p-macro key)
1336                      (update-hash-flags hash vector :key))
1337                    (mixup-hash-code (strip-tag-to-fixnum key))))))))
1338         (entries (nhash.vector-size vector))
1339         (vector-index (index->vector-index (hash-mod hash-code entries vector)))
1340         (table-key (%svref vector vector-index))
1341         (reuse (not (hash-lock-free-p hash))))
1342    (declare (fixnum hash-code vector-index))
1343    (if (or (eq key table-key)
1344            (eq table-key free-hash-marker))
1345      vector-index
1346      (let* ((secondary-hash (%svref secondary-keys-*-2
1347                                     (logand 7 hash-code)))
1348             (initial-index vector-index)             
1349             (first-deleted-index (and reuse
1350                                       (eq table-key deleted-hash-key-marker)
1351                                       vector-index))
1352             (count (+ entries entries))
1353             (length (+ count $nhash.vector_overhead)))
1354        (declare (fixnum secondary-hash initial-index count length))
1355        (loop
1356          (incf vector-index secondary-hash)
1357          (when (>= vector-index length)
1358            (decf vector-index count))
1359          (setq table-key (%svref vector vector-index))
1360          (when (= vector-index initial-index)
1361            (return (or first-deleted-index
1362                        (error "Bug: no room in table"))))
1363          (if (eq table-key key)
1364            (return vector-index)
1365            (if (eq table-key free-hash-marker)
1366              (return (or first-deleted-index vector-index))
1367              (if (and reuse
1368                       (null first-deleted-index)
1369                       (eq table-key deleted-hash-key-marker))
1370                (setq first-deleted-index vector-index)))))))))
1371
1372(defun eql-hash-find (hash key)
1373  (declare (optimize (speed 3) (safety 0)))
1374  (if (need-use-eql key)
1375    (let* ((vector (nhash.vector hash))
1376           (hash-code (%%eqlhash-internal key))
1377           (entries (nhash.vector-size vector))
1378           (vector-index (index->vector-index (hash-mod hash-code entries vector)))
1379           (table-key (%svref vector vector-index)))
1380      (declare (fixnum hash-code entries vector-index))
1381      (if (eql key table-key)
1382        vector-index
1383        (if (eq table-key free-hash-marker)
1384          -1
1385          (let* ((secondary-hash (%svref secondary-keys-*-2
1386                                         (logand 7 hash-code)))
1387                 (initial-index vector-index)
1388                 (count (+ entries entries))
1389                 (length (+ count $nhash.vector_overhead)))
1390            (declare (fixnum secondary-hash initial-index count length))
1391            (loop
1392              (incf vector-index secondary-hash)
1393              (when (>= vector-index length)
1394                (decf vector-index count))
1395              (setq table-key (%svref vector vector-index))
1396              (when (= vector-index initial-index)
1397                (return -1))
1398              (if (eql table-key key)
1399                (return vector-index)
1400                (when (eq table-key free-hash-marker)
1401                  (return -1))))))))
1402    (eq-hash-find hash key)))
1403
1404(defun eql-hash-find-for-put (hash key)
1405  (declare (optimize (speed 3) (safety 0)))
1406  (if (need-use-eql key)
1407    (let* ((vector (nhash.vector hash))
1408           (hash-code (%%eqlhash-internal key))
1409           (entries (nhash.vector-size vector))
1410           (vector-index (index->vector-index (hash-mod hash-code entries vector)))
1411           (table-key (%svref vector vector-index))
1412           (reuse (not (hash-lock-free-p hash))))
1413      (declare (fixnum hash-code entries vector-index))
1414      (if (or (eql key table-key)
1415              (eq table-key free-hash-marker))
1416        vector-index
1417        (let* ((secondary-hash (%svref secondary-keys-*-2
1418                                       (logand 7 hash-code)))
1419               (initial-index vector-index)
1420               (first-deleted-index (and reuse
1421                                         (eq table-key deleted-hash-key-marker)
1422                                         vector-index))
1423               (count (+ entries entries))
1424               (length (+ count $nhash.vector_overhead)))
1425          (declare (fixnum secondary-hash initial-index count length))
1426          (loop
1427            (incf vector-index secondary-hash)
1428            (when (>= vector-index length)
1429              (decf vector-index count))
1430            (setq table-key (%svref vector vector-index))
1431            (when (= vector-index initial-index)
1432              (return (or first-deleted-index
1433                          (error "Bug: no room in table"))))
1434            (if (eql table-key key)
1435              (return vector-index)
1436              (if (eq table-key free-hash-marker)
1437                (return (or first-deleted-index vector-index))
1438                (if (and reuse
1439                         (null first-deleted-index)
1440                         (eq table-key deleted-hash-key-marker))
1441                  (setq first-deleted-index vector-index))))))))
1442    (eq-hash-find-for-put hash key)))
1443
1444(defun %make-rehash-bits (hash &optional (size (nhash.vector-size (nhash.vector hash))))
1445  (declare (fixnum size))
1446  (let ((rehash-bits (nhash.rehash-bits hash)))
1447    (unless (and rehash-bits
1448                 (>= (uvsize rehash-bits) size))
1449      (return-from %make-rehash-bits
1450        (setf (nhash.rehash-bits hash) (make-array size :element-type 'bit :initial-element 0))))
1451    (fill (the simple-bit-vector rehash-bits) 0)))
1452
1453;;; Rehash.  Caller should have exclusive access to the hash table
1454;;; and have disabled interrupts.
1455(defun %rehash (hash)
1456  (when (hash-lock-free-p hash)
1457    (error "How did we get here?"))
1458  (let* ((vector (nhash.vector hash))
1459         (flags (nhash.vector.flags vector))
1460         (vector-index (- $nhash.vector_overhead 2))
1461         (size (nhash.vector-size vector))
1462         (rehash-bits (%make-rehash-bits hash size))
1463         (index -1))
1464    (declare (fixnum size index vector-index))
1465    (setf (nhash.vector.flags vector)
1466          (logand flags $nhash-clear-key-bits-mask))
1467    (setf (nhash.vector.cache-key vector) free-hash-marker
1468          (nhash.vector.cache-value vector) nil)
1469    (%set-does-not-need-rehashing vector)
1470    (loop
1471      (when (>= (incf index) size) (return))
1472      (setq vector-index (+ vector-index 2))
1473      (unless (%already-rehashed-p index rehash-bits)
1474        (let* ((key (%svref vector vector-index))
1475               (deleted (eq key deleted-hash-key-marker)))
1476          (unless
1477            (when (or deleted (eq key free-hash-marker))
1478              (if deleted  ; one less deleted entry
1479                (let ((count (1- (nhash.vector.deleted-count vector))))
1480                  (declare (fixnum count))
1481                  (setf (nhash.vector.deleted-count vector) count)
1482                  (if (< count 0)
1483                    (let ((wdc (nhash.vector.weak-deletions-count vector)))
1484                      (setf (nhash.vector.weak-deletions-count vector) 0)
1485                      (incf (nhash.vector.deleted-count vector) wdc)
1486                      (decf (nhash.vector.count vector) wdc)))
1487                  (incf (nhash.grow-threshold hash))
1488                  ;; Change deleted to free
1489                  (setf (%svref vector vector-index) free-hash-marker)))
1490              t)
1491            (let* ((last-index index)
1492                   (value (%svref vector (the fixnum (1+ vector-index))))
1493                   (first t))
1494                (loop
1495                  (let ((vector (nhash.vector hash))
1496                        (found-index (%rehash-probe rehash-bits hash key)))
1497                    (%set-already-rehashed-p found-index rehash-bits)
1498                    (if (eq last-index found-index)
1499                      (return)
1500                      (let* ((found-vector-index (index->vector-index found-index))
1501                             (newkey (%svref vector found-vector-index))
1502                             (newvalue (%svref vector (the fixnum (1+ found-vector-index)))))
1503                        (declare (fixnum found-vector-index))
1504                        (when first ; or (eq last-index index) ?
1505                          (setq first nil)
1506                          (setf (%svref vector vector-index) free-hash-marker)
1507                          (setf (%svref vector (the fixnum (1+ vector-index))) free-hash-marker))
1508                        (%set-hash-table-vector-key vector found-vector-index key)
1509                        (setf (%svref vector (the fixnum (1+ found-vector-index))) value)                       
1510                        (when (or (eq newkey free-hash-marker)
1511                                  (setq deleted (eq newkey deleted-hash-key-marker)))
1512                          (when deleted
1513                            (let ((count (1- (nhash.vector.deleted-count vector))))
1514                              (declare (fixnum count))
1515                              (setf (nhash.vector.deleted-count vector) count)
1516                              (if (< count 0)
1517                                (let ((wdc (nhash.vector.weak-deletions-count vector)))
1518                                  (setf (nhash.vector.weak-deletions-count vector) 0)
1519                                  (incf (nhash.vector.deleted-count vector) wdc)
1520                                  (decf (nhash.vector.count vector) wdc)))
1521                              (incf (nhash.grow-threshold hash))))
1522                          (return))
1523                        (when (eq key newkey)
1524                          (cerror "Delete one of the entries." "Duplicate key: ~s in ~s ~s ~s ~s ~s"
1525                                  key hash value newvalue index found-index)                       
1526                          (decf (nhash.vector.count vector))
1527                          (incf (nhash.grow-threshold hash))
1528                          (return))
1529                        (setq key newkey
1530                              value newvalue
1531                              last-index found-index)))))))))))
1532    t )
1533
1534;;; Hash to an index that is not set in rehash-bits
1535 
1536(defun %rehash-probe (rehash-bits hash key &optional (vector (nhash.vector hash)))
1537  (declare (optimize (speed 3)(safety 0))) 
1538  (multiple-value-bind (hash-code index entries)(compute-hash-code hash key t vector)
1539    (declare (fixnum hash-code index entries))
1540    (when (null hash-code)(cerror "nuts" "Nuts"))
1541    (let* ((vector-index (index->vector-index index)))
1542      (if (or (not (%already-rehashed-p index rehash-bits))
1543              (eq key (%svref vector vector-index)))
1544        (return-from %rehash-probe index)
1545        (let ((second (%svref secondary-keys (%ilogand 7 hash-code))))
1546          (declare (fixnum second))
1547          (loop
1548            (setq index (+ index second))
1549            (when (>= index entries)
1550              (setq index (- index entries)))
1551            (when (or (not (%already-rehashed-p index rehash-bits))
1552                      (eq key (%svref vector (index->vector-index index))))
1553              (return-from %rehash-probe index))))))))
1554
1555;;; Returns one value: the index of the entry in the vector
1556;;; Since we're growing, we don't need to compare and can't find a key that's
1557;;; already there.
1558(defun %growhash-probe (vector hash key)
1559  (declare (optimize (speed 3)(safety 0)))
1560  (multiple-value-bind (hash-code index entries)(compute-hash-code hash key t vector)
1561    (declare (fixnum hash-code index entries))
1562    (let* ((vector-index (index->vector-index  index))
1563           (vector-key nil))
1564      (declare (fixnum vector-index))
1565      (if (or (eq free-hash-marker
1566                  (setq vector-key (%svref vector vector-index)))
1567              (eq deleted-hash-key-marker vector-key))
1568        (return-from %growhash-probe index)
1569        (let ((second (%svref secondary-keys (%ilogand 7 hash-code))))
1570          (declare (fixnum second))
1571          (loop
1572            (setq index (+ index second))
1573            (when (>= index entries)
1574              (setq index (- index entries)))
1575            (when (or (eq free-hash-marker
1576                          (setq vector-key (%svref vector (index->vector-index index))))
1577                      (eq deleted-hash-key-marker vector-key))
1578              (return-from %growhash-probe index))))))))
1579
1580;;;;;;;;;;;;;
1581;;
1582;; Mapping functions are in "ccl:lib;hash"
1583;;
1584
1585
1586
1587;;;;;;;;;;;;;
1588;;
1589;; Hashing functions
1590;; EQ & the EQ part of EQL are done in-line.
1591;;
1592
1593
1594
1595
1596
1597
1598
1599
1600
1601;;; so whats so special about bit vectors as opposed to any other vectors of bytes
1602;;; For starters, it's guaranteed that they exist in the implementation; that may
1603;;; not be true of other immediate vector types.
1604(defun bit-vector-hash (bv)
1605  (declare (optimize (speed 3)(safety 0)))
1606  (let ((length (length bv)))
1607    (declare (fixnum length)) ;will this always be true? it's true of all vectors.
1608    (multiple-value-bind (data offset) (array-data-and-offset bv)
1609      (declare (type simple-bit-vector data) (fixnum offset))
1610      (let* ((hash 0)
1611             (limit (+ length offset))
1612             (nbytes (ash (the fixnum (+ length 7)) -3)))
1613        (declare (fixnum hash limit nbytes))
1614        (dotimes (i nbytes (mixup-hash-code hash))
1615          (let* ((w 0))
1616            (declare (fixnum w))
1617            (dotimes (j 8 (setq hash (+ (the fixnum (ash hash -3))  w)))
1618              (setq w (the fixnum
1619                        (logxor
1620                         (the fixnum
1621                           (ash (if (< offset limit) 
1622                                  (the fixnum (sbit data offset))
1623                                  0)
1624                                (the fixnum j)))
1625                         w)))
1626              (incf offset))))))))
1627
1628#|
1629(defun bit-vector-hash (bv)
1630  (declare (optimize (speed 3)(safety 0)))
1631  (let ((length (length bv)))
1632    (declare (fixnum length))
1633    (let* ((all (+ length 15))
1634           (nwds (ash all -4))
1635           (rem (logand all 15))
1636           (hash 0)
1637           (mask (ash (the fixnum (1- (the fixnum (expt 2 rem))))(the fixnum(- 16 rem)))))
1638      (declare (fixnum all nwds rem hash mask))
1639      (multiple-value-bind (data offset)
1640                           (array-data-and-offset bv)
1641        (declare (fixnum offset))
1642        (locally (declare (type (simple-array (unsigned-byte 16) (*)) data))
1643          (dotimes (i nwds)
1644            (setq hash (%i+ hash (aref data (the fixnum (+ i offset))))))
1645          (when (neq 0 mask)           
1646            (setq hash (%i+ hash (%ilogand mask (aref data (the fixnum (+ offset nwds)))))))
1647          (mixup-hash-code hash))))))
1648|#
1649
1650
1651;;; Same as %%equalhash, but different:
1652;;;  1) Real numbers are hashed as if they were double-floats.  The real components of complex numbers
1653;;;     are hashed as double-floats and XORed together.
1654;;;  2) Characters and strings are hashed in a case-insensitive manner.
1655;;;  3) Hash tables are hashed based on their size and type.
1656;;;  4) Structures and CL array types are hashed based on their content.
1657
1658
1659;;; check fixnum befor immediate-p. call %%eqlhash
1660
1661(defun %%equalphash (key)
1662  (cond ((or (fixnump key)(short-float-p key))
1663         (%dfloat-hash (float key 1.0d0))) 
1664        ((immediate-p-macro key)
1665         (mixup-hash-code (strip-tag-to-fixnum (if (characterp key)(char-upcase key) key))))
1666        ((bignump key)
1667         (if (<= most-negative-double-float key most-positive-double-float)
1668           (%dfloat-hash (float key 1.0d0))  ; with-stack-double-floats
1669           (%%eqlhash-internal key)))
1670        ((double-float-p key)
1671         (%dfloat-hash key))
1672        ((ratiop key)
1673         (%ilogxor (%%equalphash (numerator key)) (%%equalphash (denominator key))))
1674        ((complexp key)
1675         (%ilogxor (%%equalphash (realpart key)) (%%equalphash (imagpart key))))
1676        ((hash-table-p key)
1677         (equalphash-hash-table key))
1678        ((or (istructp key)
1679             (structurep key))  ; was (gvectorp key)
1680         (%%equalphash-structure 11 key))
1681        ((or (arrayp key)) ;(uvectorp key)) ;??
1682         (%%equalphash-array 11 key))
1683        ((consp key)
1684         (%%equalphash-aux 11 key))
1685        (t (%%eqlhash key))))
1686
1687
1688(defun equalphash-hash-table (hash-table)
1689  (let ((hash (%%equalhash "HASH-TABLE"))
1690        addressp)
1691    (declare (fixnum hash))
1692    (incf hash (the fixnum (%%eqhash (hash-table-count hash-table))))
1693    (multiple-value-bind (h ap) (%%eqhash (nhash.comparef hash-table))
1694      (declare (fixnum h))
1695      (incf hash h)
1696      (if ap (setq addressp t)))
1697    (multiple-value-bind (h ap) (%%eqhash (nhash.keytransF hash-table))
1698      (declare (fixnum h))
1699      (incf hash h)
1700      (if ap (setq addressp t)))
1701    (values hash addressp)))
1702
1703(defun %%equalphash-structure (limit key)
1704  (let* ((size (uvsize key))
1705         (hash (mixup-hash-code size))
1706         addressp)
1707    (declare (fixnum limit size hash))
1708    (dotimes (i size)
1709      (multiple-value-bind (h ap) (%%equalphash-aux limit (%svref key i))
1710        (declare (fixnum h))
1711        (setq hash (the fixnum (+ (the fixnum (rotate-hash-code hash)) h)))
1712        (if ap (setq addressp t)))
1713      (when (<= (decf limit) 0)
1714        (setq hash (the fixnum (+ (the fixnum (rotate-hash-code hash))
1715                                  (the fixnum (mixup-hash-code 11)))))
1716        (return)))
1717    (values hash addressp)))
1718
1719(defun %%equalphash-array (limit key)
1720  (multiple-value-bind (array offset) (array-data-and-offset key)
1721    (let* ((rank (array-rank key))
1722           (vectorp (eql rank 1))
1723           (size (if vectorp (length key) (array-total-size key)))
1724           (hash (mixup-hash-code rank))
1725           addressp)
1726      (declare (fixnum size hash limit rank))
1727      (if vectorp
1728        (setq hash
1729              (the fixnum
1730                   (+ (the fixnum (rotate-hash-code hash))
1731                      (the fixnum (mixup-hash-code size)))))
1732        (dotimes (i rank)
1733          (declare (fixnum i))
1734          (setq hash
1735                (the fixnum 
1736                     (+ (the fixnum (rotate-hash-code hash))
1737                        (the fixnum
1738                             (mixup-hash-code (array-dimension key i))))))))     
1739      (dotimes (i size)
1740        (declare (fixnum i))
1741        (multiple-value-bind (h ap) (%%equalphash-aux limit (uvref array offset))
1742          (declare (fixnum h))
1743          (setq hash (the fixnum (+ (the fixnum (rotate-hash-code hash)) h)))
1744          (if ap (setq addressp t)))
1745        (when (<= (decf limit) 0)
1746          (setq hash (the fixnum (+ (the fixnum (rotate-hash-code hash))
1747                                    (the fixnum (mixup-hash-code 11)))))
1748          (return))
1749        (incf offset))
1750      (values hash addressp))))
1751
1752(defun %%equalphash-aux (limit key)
1753  (if (<= limit 0) 
1754    (mixup-hash-code 11)
1755    (if (null key) (mixup-hash-code 17)
1756        (cond ((consp key)
1757               (let ((hash 0)
1758                     address-p)
1759                 (do ((l limit (1- l)))
1760                     ((eq l 0)(values hash address-p))
1761                   (multiple-value-bind (ahash ap)
1762                                        (%%equalphash-aux l (if (consp key)(car key) key))
1763                     (setq hash (mixup-hash-code (logxor ahash hash)))
1764                     (if ap (setq address-p t)))
1765                   (when (not (consp key))
1766                     (return (values hash address-p)))
1767                   (setq key (cdr key)))))
1768              ((typep key 'hash-table)
1769               (equalphash-hash-table key))
1770              ; what are the dudes called that contain bits? they are uvectors but not gvectors?
1771              ; ivectors.
1772              ((or (istructp key)
1773                   (structurep key))    ;was (gvectorp key)
1774               (%%equalphash-structure limit key))
1775              ((or (arrayp key))  ; (uvectorp key))
1776               (%%equalphash-array limit key))
1777              (t (%%equalphash key))))))
1778
1779(defun alist-hash-table (alist &rest hash-table-args)
1780  (declare (dynamic-extent hash-table-args))
1781  (if (typep alist 'hash-table)
1782    alist
1783    (let ((hash-table (apply #'make-hash-table hash-table-args)))
1784      (dolist (cons alist) (puthash (car cons) hash-table (cdr cons)))
1785      hash-table)))
1786
1787(defun %hash-table-equalp (x y)
1788  ;; X and Y are both hash tables
1789  (and (eq (hash-table-test x)
1790           (hash-table-test y))
1791       (eql (hash-table-count x)
1792            (hash-table-count y))
1793       (block nil
1794         (let* ((default (cons nil nil))
1795                (foo #'(lambda (k v)
1796                         (let ((y-value (gethash k y default)))
1797                           (unless (and (neq default y-value)
1798                                        (equalp v y-value))
1799                             (return nil))))))
1800           (declare (dynamic-extent foo default))
1801           (maphash foo x))
1802         t)))
1803
1804(defun sxhash (s-expr)
1805  "Computes a hash code for S-EXPR and returns it as an integer."
1806  (logand (sxhash-aux s-expr 7 17) target::target-most-positive-fixnum))
1807
1808(defun sxhash-aux (expr counter key)
1809  (declare (fixnum counter))
1810  (if (> counter 0)
1811    (typecase expr
1812      ((or string bit-vector number character)  (+ key (%%equalhash expr)))
1813      (logical-pathname
1814       (dotimes (i (uvsize expr) key)
1815         (declare (fixnum i))
1816         (setq key (+ key (sxhash-aux (%svref expr i) (1- counter) key)))))
1817      (pathname
1818       ;; Don't consider %PHYSICAL-PATHNAME-VERSION to be significant
1819       (dotimes (i (uvsize expr) key)
1820         (declare (fixnum i))
1821         (unless (= i %physical-pathname-version)
1822           (setq key (+ key (sxhash-aux (%svref expr i) (1- counter) key))))))
1823      (symbol (+ key (%%equalhash (symbol-name expr))))
1824      (cons (sxhash-aux
1825             (cdr expr)
1826             (the fixnum (1- counter))             
1827             (+ key (sxhash-aux (car expr) (the fixnum (1- counter)) key))))
1828      (t (+  key (%%equalhash (symbol-name (%type-of expr))))))
1829    key))
1830
1831
1832
1833#+(or ppc32-target x8632-target)
1834(defun immediate-p (thing)
1835  (let* ((tag (lisptag thing)))
1836    (declare (fixnum tag))
1837    (or (= tag target::tag-fixnum)
1838        (= tag target::tag-imm))))
1839
1840#+ppc64-target
1841(defun immediate-p (thing)
1842  (let* ((tag (lisptag thing)))
1843    (declare (fixnum tag))
1844    (or (= tag ppc64::tag-fixnum)
1845        (= (logand tag ppc64::lowtagmask) ppc64::lowtag-imm))))
1846
1847#+x8664-target
1848(defun immediate-p (thing)
1849  (let* ((tag (lisptag thing)))
1850    (declare (type (unsigned-byte 3) tag))
1851    (logbitp tag
1852             (logior (ash 1 x8664::tag-fixnum)
1853                     (ash 1 x8664::tag-imm-0)
1854                     (ash 1 x8664::tag-imm-1)))))
1855
1856
1857
1858(defun %cons-nhash-vector (size &optional (flags 0))
1859  (declare (fixnum size))
1860  (let* ((vector (%alloc-misc (+ (+ size size) $nhash.vector_overhead) target::subtag-hash-vector free-hash-marker)))
1861    (%init-nhash-vector vector flags)
1862    vector))
1863
1864(defun %init-nhash-vector (vector flags)
1865  (let ((size (vector-index->index (uvsize vector))))
1866    (declare (fixnum size))
1867    (setf (nhash.vector.link vector) 0
1868          (nhash.vector.flags vector) flags
1869          (nhash.vector.gc-count vector) (%get-gc-count)
1870          (nhash.vector.free-alist vector) nil
1871          (nhash.vector.finalization-alist vector) nil
1872          (nhash.vector.weak-deletions-count vector) 0
1873          (nhash.vector.hash vector) nil
1874          (nhash.vector.deleted-count vector) 0
1875          (nhash.vector.count vector) 0
1876          (nhash.vector.cache-key vector) free-hash-marker
1877          (nhash.vector.cache-value vector) nil
1878          (nhash.vector.cache-idx vector) nil
1879          (nhash.vector.size vector) size
1880          (nhash.vector.size-reciprocal vector) (floor (ash 1 (- target::nbits-in-word target::fixnumshift)) size))))
1881
1882(defun assert-hash-table-readonly (hash)
1883  (unless (typep hash 'hash-table)
1884    (report-bad-arg hash 'hash-table))
1885  (or (nhash.read-only hash)
1886      (when (nhash.owner hash)
1887        (error "Hash~table ~s is thread-private and can't be made read-only for that reason" hash))
1888      (if (hash-lock-free-p hash)
1889        (setf (nhash.read-only hash) t)
1890        (with-lock-context
1891          (without-interrupts
1892           (write-lock-hash-table hash)
1893           (let* ((flags (nhash.vector.flags (nhash.vector hash))))
1894             (declare (fixnum flags))
1895             (when (or (logbitp $nhash_track_keys_bit flags)
1896                       (logbitp $nhash_component_address_bit flags))
1897               (format t "~&Hash-table ~s uses address-based hashing and can't yet be made read-only for that reason." hash)
1898               (unlock-hash-table hash nil)
1899               (return-from assert-hash-table-readonly nil))
1900             (setf (nhash.read-only hash) t)
1901             (unlock-hash-table hash nil)
1902             t))))))
1903
1904;; This is dangerous, if multiple threads are accessing a read-only
1905;; hash table. Use it responsibly.
1906(defun assert-hash-table-writeable (hash)
1907  (unless (typep hash 'hash-table)
1908    (report-bad-arg hash 'hash-table))
1909  (when (nhash.read-only hash)
1910    (setf (nhash.read-only hash) nil)
1911    t))
1912
1913(defun readonly-hash-table-p (hash)
1914  (unless (typep hash 'hash-table)
1915    (report-bad-arg hash 'hash-table))
1916  (nhash.read-only hash))
1917
1918(defun hash-table-owner (hash)
1919  (unless (typep hash 'hash-table)
1920    (report-bad-arg hash 'hash-table))
1921  (nhash.owner hash))
1922
1923(defun claim-hash-table (hash &optional steal)
1924  (unless (typep hash 'hash-table)
1925    (report-bad-arg hash 'hash-table))
1926  (let* ((owner (nhash.owner hash)))
1927    (if owner
1928      (or (eq owner *current-process*)
1929          (when steal
1930            (setf (nhash.owner hash) *current-process*)))
1931      (progn
1932        (unless (hash-lock-free-p hash)
1933          (write-lock-hash-table hash)
1934          (setf (nhash.exclusion-lock hash) nil))
1935        (setf (nhash.owner hash) *current-process*)
1936        t))))
1937
1938 
1939;; ** TODO: for lock-free hash tables, we don't need to copy,
1940;; we could map over the actual hash table vector, because it's
1941;; always valid.
1942(defun lock-free-enumerate-hash-keys-and-values (hash keys values)
1943  (do* ((in (nhash.vector hash))
1944        (in-idx $nhash.vector_overhead (+ in-idx 2))
1945        (insize (uvsize in))
1946        (outsize (length (or keys values)))
1947        (out-idx 0))
1948       ((or (= in-idx insize)
1949            (= out-idx outsize))
1950        out-idx)
1951    (declare (fixnum in-idx insize out-idx outsize))
1952    (let* ((key (%svref in in-idx)))
1953      (unless (eq key free-hash-marker)
1954        (let ((val (%svref in (%i+ in-idx 1))))
1955          (when (eq val rehashing-value-marker)
1956            ;; This table is being rehashed.  Wait to finish and try again
1957            (lock-free-rehash hash)
1958            (return-from lock-free-enumerate-hash-keys-and-values
1959                         (lock-free-enumerate-hash-keys-and-values hash keys values)))
1960          (unless (eq val free-hash-marker)
1961            (when (eql key deleted-hash-key-marker)
1962              (error "Bug: deleted key but not value?"))
1963            (when keys (setf (%svref keys out-idx) key))
1964            (when values (setf (%svref values out-idx) val))
1965            (incf out-idx)))))))
1966
1967(defun enumerate-hash-keys-and-values (hash keys values)
1968  (unless (typep hash 'hash-table)
1969    (report-bad-arg hash 'hash-table))
1970  (when (hash-lock-free-p hash)
1971    (return-from enumerate-hash-keys-and-values
1972                 (lock-free-enumerate-hash-keys-and-values hash keys values)))
1973  (with-lock-context
1974    (without-interrupts
1975     (let* ((readonly (eq (read-lock-hash-table hash) :readonly)))
1976       (do* ((in (nhash.vector hash))
1977             (in-idx $nhash.vector_overhead (+ in-idx 2))
1978             (insize (uvsize in))
1979             (outsize (length (or keys values)))
1980             (out-idx 0))
1981           ((or (= in-idx insize)
1982                (= out-idx outsize))
1983              (unlock-hash-table hash readonly)
1984              out-idx)
1985         (declare (fixnum in-idx insize out-idx outsize))
1986         (let* ((key (%svref in in-idx)))
1987           (unless (or (eq key free-hash-marker)
1988                       (eq key deleted-hash-key-marker))
1989             (when keys
1990               (setf (%svref keys out-idx) key))
1991             (when values
1992               (setf (%svref values out-idx) (%svref in (%i+ in-idx 1))))
1993             (incf out-idx))))))))
1994
1995(defun enumerate-hash-keys (hash out)
1996  (enumerate-hash-keys-and-values hash out nil))
Note: See TracBrowser for help on using the repository browser.