source: branches/ia32/level-1/l1-sockets.lisp @ 7666

Last change on this file since 7666 was 7666, checked in by rme, 12 years ago

Merge trunk changes r7361:7663.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 51.3 KB
Line 
1;;;-*- Mode: Lisp; Package: CCL -*-
2;;;
3;;;   Copyright (C) 2001 Clozure Associates
4;;;   This file is part of OpenMCL. 
5;;;
6;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
7;;;   License , known as the LLGPL and distributed with OpenMCL as the
8;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
9;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
10;;;   conflict, the preamble takes precedence. 
11;;;
12;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
13;;;
14;;;   The LLGPL is also available online at
15;;;   http://opensource.franz.com/preamble.html
16
17(in-package "CCL")
18
19
20
21;;; basic socket API
22(eval-when (:compile-toplevel :load-toplevel :execute)
23  (export '(MAKE-SOCKET
24            ACCEPT-CONNECTION
25            DOTTED-TO-IPADDR
26            IPADDR-TO-DOTTED
27            IPADDR-TO-HOSTNAME
28            LOOKUP-HOSTNAME
29            LOOKUP-PORT
30            ;;with-pending-connect
31            RECEIVE-FROM
32            SEND-TO
33            SHUTDOWN
34            ;;socket-control
35            SOCKET-OS-FD
36            REMOTE-HOST
37            REMOTE-PORT
38            REMOTE-FILENAME
39            LOCAL-HOST
40            LOCAL-PORT
41            LOCAL-FILENAME
42            SOCKET-ADDRESS-FAMILY
43            SOCKET-CONNECT
44            SOCKET-FORMAT
45            SOCKET-TYPE
46            SOCKET-ERROR
47            SOCKET-ERROR-CODE
48            SOCKET-ERROR-IDENTIFIER
49            SOCKET-ERROR-SITUATION
50            WITH-OPEN-SOCKET)))
51
52;;; The PPC is big-endian (uses network byte order), which makes
53;;; things like #_htonl and #_htonl no-ops.  These functions aren't
54;;; necessarily defined as functions in some header files (I'm sure
55;;; that that either complies with or violates some C standard), and
56;;; it doesn't seem to make much sense to fight that to do ff-calls
57;;; to a couple of identity functions.
58
59#+big-endian-target
60(progn
61  (defmacro HTONL (x) x)
62  (defmacro HTONS (x) x)
63  (defmacro NTOHL (x) x)
64  (defmacro NTOHS (x) x))
65
66#+little-endian-target
67(progn
68  (declaim (inline %bswap32 %bswap16))
69  (defun %bswap32 (x)
70    (declare (type (unsigned-byte 32) x))
71    (%swap-u32 x))
72  (defun %bswap16 (x)
73    (declare (type (unsigned-byte 16) x))
74    (%swap-u16 x))
75  (defmacro HTONL (x) `(%bswap32 ,x))
76  (defmacro HTONS (x) `(%bswap16 ,x))
77  (defmacro NTOHL (x) `(%bswap32 ,x))
78  (defmacro NTOHS (x) `(%bswap16 ,x)))
79
80(defparameter *default-socket-character-encoding*
81  nil)
82
83(defmethod default-character-encoding ((domain (eql :socket)))
84  *default-socket-character-encoding*)
85 
86
87;;; On some (hypothetical) little-endian platform, we might want to
88;;; define HTONL and HTONS to actually swap bytes around.
89
90(defpackage "OPENMCL-SOCKET"
91  (:use "CL")
92  (:import-from "CCL"
93                "MAKE-SOCKET"
94                "ACCEPT-CONNECTION"
95                "DOTTED-TO-IPADDR"
96                "IPADDR-TO-DOTTED"
97                "IPADDR-TO-HOSTNAME"
98                "LOOKUP-HOSTNAME"
99                "LOOKUP-PORT"
100                ;;with-pending-connect
101                "RECEIVE-FROM"
102                "SEND-TO"
103                "SHUTDOWN"
104                ;;socket-control
105                "SOCKET-OS-FD"
106                "REMOTE-HOST"
107                "REMOTE-PORT"
108                "REMOTE-FILENAME"
109                "LOCAL-HOST"
110                "LOCAL-PORT"
111                "LOCAL-FILENAME"
112                "SOCKET-ADDRESS-FAMILY"
113                "SOCKET-CONNECT"
114                "SOCKET-FORMAT"
115                "SOCKET-TYPE"
116                "SOCKET-ERROR"
117                "SOCKET-ERROR-CODE"
118                "SOCKET-ERROR-IDENTIFIER"
119                "SOCKET-ERROR-SITUATION"
120                "WITH-OPEN-SOCKET")
121  (:export  "MAKE-SOCKET"
122            "ACCEPT-CONNECTION"
123            "DOTTED-TO-IPADDR"
124            "IPADDR-TO-DOTTED"
125            "IPADDR-TO-HOSTNAME"
126            "LOOKUP-HOSTNAME"
127            "LOOKUP-PORT"
128            ;;with-pending-connect
129            "RECEIVE-FROM"
130            "SEND-TO"
131            "SHUTDOWN"
132            ;;socket-control
133            "SOCKET-OS-FD"
134            "REMOTE-HOST"
135            "REMOTE-PORT"
136            "REMOTE-FILENAME"
137            "LOCAL-HOST"
138            "LOCAL-PORT"
139            "LOCAL-FILENAME"
140            "SOCKET-ADDRESS-FAMILY"
141            "SOCKET-CONNECT"
142            "SOCKET-FORMAT"
143            "SOCKET-TYPE"
144            "SOCKET-ERROR"
145            "SOCKET-ERROR-CODE"
146            "SOCKET-ERROR-IDENTIFIER"
147            "SOCKET-ERROR-SITUATION"
148            "WITH-OPEN-SOCKET"))
149
150(eval-when (:compile-toplevel)
151  #+linuxppc-target
152  (require "PPC-LINUX-SYSCALLS")
153  #+linuxx8664-target
154  (require "X8664-LINUX-SYSCALLS")
155  #+darwinppc-target
156  (require "DARWINPPC-SYSCALLS")
157  #+darwinx8664-target
158  (require "DARWINX8664-SYSCALLS")
159  #+freebsdx8664-target
160  (require "X8664-FREEBSD-SYSCALLS")
161  )
162
163(define-condition socket-error (simple-stream-error)
164  ((code :initarg :code :reader socket-error-code)
165   (identifier :initform :unknown :initarg :identifier :reader socket-error-identifier)
166   (Situation :initarg :situation :reader socket-error-situation)))
167
168(define-condition socket-creation-error (simple-error)
169  ((code :initarg :code :reader socket-creation-error-code)
170   (identifier :initform :unknown :initarg :identifier :reader socket-creationg-error-identifier)
171   (situation :initarg :situation :reader socket-creation-error-situation)))
172
173(defvar *socket-error-identifiers*
174  (list #$EADDRINUSE :address-in-use
175        #$ECONNABORTED :connection-aborted
176        #$ENOBUFS :no-buffer-space
177        #$ENOMEM :no-buffer-space
178        #$ENFILE :no-buffer-space
179        #$ETIMEDOUT :connection-timed-out
180        #$ECONNREFUSED :connection-refused
181        #$ENETUNREACH :host-unreachable
182        #$EHOSTUNREACH :host-unreachable
183        #$EHOSTDOWN :host-down
184        #$ENETDOWN :network-down
185        #$EADDRNOTAVAIL :address-not-available
186        #$ENETRESET :network-reset
187        #$ECONNRESET :connection-reset
188        #$ESHUTDOWN :shutdown
189        #$EACCES :access-denied
190        #$EPERM :access-denied))
191
192
193(declaim (inline socket-call))
194(defun socket-call (stream where res)
195  (if (< res 0)
196    (socket-error stream where res)
197    res))
198
199(defun %hstrerror (h_errno)
200  (with-macptrs ((p (#_hstrerror (abs h_errno))))
201    (if p
202      (%get-cstring p)
203      (format nil "Nameserver error ~d" (abs h_errno)))))
204   
205
206
207
208(defun socket-error (stream where errno &optional nameserver-p)
209  "Creates and signals (via error) one of two socket error
210conditions, based on the state of the arguments."
211  (when (< errno 0)
212    (setq errno (- errno)))
213  (if stream
214    (error (make-condition 'socket-error
215                           :stream stream
216                           :code errno
217                           :identifier (getf *socket-error-identifiers* errno :unknown)
218                           :situation where
219                           ;; TODO: this is a constant arg, there is a way to put this
220                           ;; in the class definition, just need to remember how...
221                           :format-control "~a (error #~d) on ~s in ~a"
222                           :format-arguments (list
223                                              (if nameserver-p
224                                                (%hstrerror errno)
225                                                (%strerror errno))
226                                              errno stream where)))
227    (error (make-condition 'socket-creation-error
228                           :code errno
229                           :identifier (getf *socket-error-identifiers* errno :unknown)
230                           :situation where
231                           ;; TODO: this is a constant arg, there is a way to put this
232                           ;; in the class definition, just need to remember how...
233                           :format-control "~a (error #~d) on ~s in ~a"
234                           :format-arguments (list
235                                              (if nameserver-p
236                                                (%hstrerror errno)
237                                                (%strerror errno))
238                                              errno stream where)))))
239   
240
241
242;; If true, this will try to allow other processes to run while
243;; socket io is happening.
244(defvar *multiprocessing-socket-io* t)
245
246(defclass socket ()
247  ())
248
249(defmacro with-open-socket ((var . args) &body body
250                            &aux (socket (make-symbol "socket"))
251                                 (done (make-symbol "done")))
252  "Execute body with var bound to the result of applying make-socket to
253make-socket-args. The socket gets closed on exit."
254  `(let (,socket ,done)
255     (unwind-protect
256         (multiple-value-prog1
257           (let ((,var (setq ,socket (make-socket ,@args))))
258             ,@body)
259           (setq ,done t))
260       (when ,socket (close ,socket :abort (not ,done))))))
261
262(defgeneric socket-address-family (socket)
263  (:documentation "Return :internet or :file, as appropriate."))
264
265(defclass ip-socket (socket)
266  ())
267
268(defmethod socket-address-family ((socket ip-socket)) :internet)
269
270(defclass file-socket (socket)
271  ())
272
273(defmethod socket-address-family ((socket file-socket)) :file)
274
275(defclass tcp-socket (ip-socket)
276  ())
277
278(defgeneric socket-type (socket)
279  (:documentation
280   "Return :stream for tcp-stream and listener-socket, and :datagram
281for udp-socket."))
282
283(defmethod socket-type ((socket tcp-socket)) :stream)
284
285(defclass stream-file-socket (file-socket)
286  ())
287
288(defmethod socket-type ((socket stream-file-socket)) :stream)
289
290
291;;; An active TCP socket is an honest-to-goodness stream.
292(defclass tcp-stream (tcp-socket)
293  ())
294
295(defclass fundamental-tcp-stream (tcp-stream
296                                  fd-stream
297                                  buffered-binary-io-stream-mixin
298                                  buffered-character-io-stream-mixin)
299    ())
300
301(make-built-in-class 'basic-tcp-stream
302                     'tcp-stream
303                     'basic-binary-io-stream
304                     'basic-character-io-stream)
305
306(defgeneric socket-connect (stream)
307 (:documentation
308   "Return :active for tcp-stream, :passive for listener-socket, and NIL
309for udp-socket"))
310
311(defmethod socket-connect ((stream tcp-stream)) :active)
312
313(defgeneric socket-format (stream)
314  (:documentation
315   "Return the socket format as specified by the :format argument to
316make-socket."))
317
318(defmethod socket-format ((stream tcp-stream))
319  (if (eq (stream-element-type stream) 'character)
320    :text
321    ;; Should distinguish between :binary and :bivalent, but hardly
322    ;; seems worth carrying around an extra slot just for that.
323    :bivalent))
324
325(defmethod socket-device ((stream tcp-stream))
326  (let ((ioblock (stream-ioblock stream nil)))
327    (and ioblock (ioblock-device ioblock))))
328
329(defmethod select-stream-class ((class tcp-stream) in-p out-p char-p)
330  (declare (ignore char-p)) ; TODO: is there any real reason to care about this?
331  ;; Yes, in general.  There is.
332  (assert (and in-p out-p) () "Non-bidirectional tcp stream?")
333  'fundamental-tcp-stream)
334
335(defmethod map-to-basic-stream-class-name ((name (eql 'tcp-stream)))
336  'basic-tcp-stream)
337
338(defmethod select-stream-class ((s (eql 'basic-tcp-stream)) in-p out-p char-p)
339  (declare (ignore char-p))
340  (assert (and in-p out-p) () "Non-bidirectional tcp stream?")
341  'basic-tcp-stream)
342
343;;; A FILE-SOCKET-STREAM is also honest. To goodness.
344(defclass file-socket-stream (stream-file-socket)
345  ())
346
347(defclass fundamental-file-socket-stream (file-socket-stream
348                                          fd-stream
349                                          buffered-binary-io-stream-mixin
350                                          buffered-character-io-stream-mixin)
351    ())
352
353(make-built-in-class 'basic-file-socket-stream
354                     'file-socket-stream
355                     'basic-binary-io-stream
356                     'basic-character-io-stream)
357
358
359(defmethod map-to-basic-stream-class-name ((name (eql 'file-socket-stream)))
360  'basic-file-socket-stream)
361
362(defmethod select-stream-class ((class file-socket-stream) in-p out-p char-p)
363  (declare (ignore char-p)) ; TODO: is there any real reason to care about this?
364  (assert (and in-p out-p) () "Non-bidirectional file-socket stream?")
365  'fundamental-file-socket-stream)
366
367(defmethod select-stream-class ((s (eql 'basic-file-socket-stream)) in-p out-p char-p)
368  (declare (ignore char-p))
369  (assert (and in-p out-p) () "Non-bidirectional file-socket stream?")
370  'basic-file-socket-stream)
371
372(defclass unconnected-socket (socket)
373  ((device :initarg :device :accessor socket-device)
374   (keys :initarg :keys :reader socket-keys)))
375
376(defmethod socket-format ((socket unconnected-socket))
377  (or (getf (socket-keys socket) :format) :text))
378
379(defgeneric close (socket &key abort)
380  (:documentation
381   "The close generic function can be applied to sockets. It releases the
382operating system resources associated with the socket."))
383
384(defmethod close ((socket unconnected-socket) &key abort)
385  (declare (ignore abort))
386  (when (socket-device socket)
387    (fd-close (socket-device socket))
388    (setf (socket-device socket) nil)
389    t))
390
391;; A passive tcp socket just generates connection streams
392(defclass listener-socket (tcp-socket unconnected-socket) ())
393
394(defmethod SOCKET-CONNECT ((stream listener-socket)) :passive)
395
396(defclass file-listener-socket (stream-file-socket unconnected-socket) ())
397
398(defmethod SOCKET-CONNECT ((stream file-listener-socket)) :passive)
399
400;;; A FILE-LISTENER-SOCKET should try to delete the filesystem
401;;; entity when closing.
402
403(defmethod close :before ((s file-listener-socket) &key abort)
404  (declare (ignore abort))
405  (let* ((path (local-socket-filename (socket-device s) s)))
406    (when path (%delete-file path))))
407
408
409;; A udp socket just sends and receives packets.
410(defclass udp-socket (ip-socket unconnected-socket) ())
411
412(defmethod socket-type ((stream udp-socket)) :datagram)
413(defmethod socket-connect ((stream udp-socket)) nil)
414
415(defgeneric socket-os-fd (socket)
416  (:documentation
417   "Return the native OS's representation of the socket, or NIL if the
418socket is closed. On Unix, this is the Unix 'file descriptor', a small
419non-negative integer. Note that it is rather dangerous to mess around
420with tcp-stream fd's, as there is all sorts of buffering and asynchronous
421I/O going on above the OS level. listener-socket and udp-socket fd's are
422safer to mess with directly as there is less magic going on."))
423
424;; Returns nil for closed stream...
425(defmethod socket-os-fd ((socket socket))
426  (socket-device socket))
427
428;; Returns nil for closed stream
429(defun local-socket-info (fd type socket)
430  (and fd
431       (rlet ((sockaddr :sockaddr_in)
432              (namelen :signed))
433             (setf (pref namelen :signed) (record-length :sockaddr_in))
434             (socket-call socket "getsockname" (c_getsockname fd sockaddr namelen))
435             (when (= #$AF_INET (pref sockaddr :sockaddr_in.sin_family))
436               (ecase type
437                 (:host (ntohl (pref sockaddr :sockaddr_in.sin_addr.s_addr)))
438                 (:port (ntohs (pref sockaddr :sockaddr_in.sin_port))))))))
439
440(defun path-from-unix-address (addr)
441  (when (= #$AF_LOCAL (pref addr :sockaddr_un.sun_family))
442    #+darwin-target
443    (%str-from-ptr (pref addr :sockaddr_un.sun_path)
444                   (- (pref addr :sockaddr_un.sun_len) 2))
445    #-darwin-target
446    (%get-cstring (pref addr :sockaddr_un.sun_path))))
447
448(defun local-socket-filename (fd socket)
449  (and fd
450       (rlet ((addr :sockaddr_un)
451              (namelen :signed))
452         (setf (pref namelen :signed) (record-length :sockaddr_un))
453         (socket-call socket "getsockname" (c_getsockname fd addr namelen))
454         (path-from-unix-address addr))))
455
456(defmacro with-if ((var expr) &body body)
457  `(let ((,var ,expr))
458     (if ,var
459         (progn
460           ,@body))))     
461
462(defun remote-socket-info (socket type)
463  (with-if (fd (socket-device socket))
464    (rlet ((sockaddr :sockaddr_in)
465           (namelen :signed))
466          (setf (pref namelen :signed) (record-length :sockaddr_in))
467          (let ((err (c_getpeername fd sockaddr namelen)))
468            (cond ((eql err (- #$ENOTCONN)) nil)
469                  ((< err 0) (socket-error socket "getpeername" err))
470                  (t
471                   (when (= #$AF_INET (pref sockaddr :sockaddr_in.sin_family))
472                     (ecase type
473                       (:host (ntohl (pref sockaddr :sockaddr_in.sin_addr.s_addr)))
474                       (:port (ntohs  (pref sockaddr :sockaddr_in.sin_port)))))))))))
475
476(defun remote-socket-filename (socket)
477  (with-if (fd (socket-device socket))
478    (rlet ((addr :sockaddr_un)
479           (namelen :signed))
480          (setf (pref namelen :signed) (record-length :sockaddr_un))
481          (let* ((err (c_getsockname fd addr namelen)))
482            (cond ((eql err (- #$ENOTCONN)) nil)
483                  ((< err 0) (socket-error socket "getpeername" err))
484                  (t (path-from-unix-address addr)))))))
485
486(defgeneric local-port (socket)
487  (:documentation "Return the local port number."))
488
489(defmethod local-port ((socket socket))
490  (local-socket-info (socket-device socket) :port socket))
491
492(defgeneric local-host (socket)
493  (:documentation
494   "Return 32-bit unsigned IP address of the local host."))
495
496(defmethod local-host ((socket socket))
497  (local-socket-info (socket-device socket) :host socket))
498
499(defmethod local-filename ((socket socket))
500  (local-socket-filename socket))
501
502(defgeneric remote-host (socket)
503  (:documentation
504   "Return the 32-bit unsigned IP address of the remote host, or NIL if
505the socket is not connected."))
506
507;; Returns NIL if socket is not connected
508(defmethod remote-host ((socket socket))
509  (remote-socket-info socket :host))
510
511(defgeneric remote-port (socket)
512  (:documentation
513   "Return the remote port number, or NIL if the socket is not connected."))
514
515(defmethod remote-port ((socket socket))
516  (remote-socket-info socket :port))
517
518(defmethod remote-filename ((socket socket))
519  (remote-socket-filename socket))
520 
521(defun set-socket-options (fd-or-socket &key 
522                           keepalive
523                           reuse-address
524                           nodelay
525                           broadcast
526                           linger
527                           address-family
528                           local-port
529                           local-host
530                           local-filename
531                           type
532                           connect
533                           out-of-band-inline
534                           &allow-other-keys)
535  ;; see man socket(7) tcp(7) ip(7)
536  (multiple-value-bind (socket fd) (etypecase fd-or-socket
537                                     (socket (values fd-or-socket (socket-device fd-or-socket)))
538                                     (integer (values nil fd-or-socket)))
539   
540    (if (null address-family)
541        (setq address-family :internet))
542    (when keepalive
543      (int-setsockopt fd #$SOL_SOCKET #$SO_KEEPALIVE 1))
544    (when reuse-address
545      (int-setsockopt fd #$SOL_SOCKET #$SO_REUSEADDR 1))
546    (when broadcast
547      (int-setsockopt fd #$SOL_SOCKET #$SO_BROADCAST 1))
548    (when out-of-band-inline
549      (int-setsockopt fd #$SOL_SOCKET #$SO_OOBINLINE 1))
550    (rlet ((plinger :linger))
551          (setf (pref plinger :linger.l_onoff) (if linger 1 0)
552                (pref plinger :linger.l_linger) (or linger 0))
553          (socket-call socket "setsockopt"
554                       (c_setsockopt fd #$SOL_SOCKET #$SO_LINGER plinger (record-length :linger))))
555    (when (eq address-family :internet)
556      (when nodelay
557        (int-setsockopt fd
558                        #+linux-target #$SOL_TCP
559                        #+(or freebsd-target darwin-target) #$IPPROTO_TCP
560                        #$TCP_NODELAY 1))
561      (when (or local-port local-host)
562        (let* ((proto (if (eq type :stream) "tcp" "udp"))
563               (port-n (if local-port (port-as-inet-port local-port proto) 0))
564               (host-n (if local-host (host-as-inet-host local-host) #$INADDR_ANY)))
565          ;; Darwin includes the SIN_ZERO field of the sockaddr_in when
566          ;; comparing the requested address to the addresses of configured
567          ;; interfaces (as if the zeros were somehow part of either address.)
568          ;; "rletz" zeros out the stack-allocated structure, so those zeros
569          ;; will be 0.
570          (rletz ((sockaddr :sockaddr_in))
571                 (setf (pref sockaddr :sockaddr_in.sin_family) #$AF_INET
572                       (pref sockaddr :sockaddr_in.sin_port) port-n
573                       (pref sockaddr :sockaddr_in.sin_addr.s_addr) host-n)
574                 (socket-call socket "bind" (c_bind fd sockaddr (record-length :sockaddr_in)))))))
575    (when (and (eq address-family :file)
576               (eq connect :passive)
577               local-filename)
578      (bind-unix-socket fd local-filename))   
579    (when *multiprocessing-socket-io*
580      (socket-call socket "fcntl" (fd-set-flag fd #$O_NONBLOCK)))))
581
582;; I hope the inline declaration makes the &rest/apply's go away...
583(declaim (inline make-ip-socket))
584(defun make-ip-socket (&rest keys &key type &allow-other-keys)
585  (declare (dynamic-extent keys))
586  (ecase type
587    ((nil :stream) (apply #'make-tcp-socket keys))
588    ((:datagram) (apply #'make-udp-socket keys))))
589
590(declaim (inline make-file-socket))
591(defun make-file-socket (&rest keys &key type &allow-other-keys)
592  (declare (dynamic-extent keys))
593  (ecase type
594    ((nil :stream) (apply #'make-stream-file-socket keys))
595    (:datagram (apply #'make-datagram-file-socket keys))))
596
597(defun make-socket (&rest keys
598                    &key address-family
599                    ;; List all keys here just for error checking...
600                    ;; &allow-other-keys
601                    type connect remote-host remote-port eol format
602                    keepalive reuse-address nodelay broadcast linger
603                    local-port local-host backlog class out-of-band-inline
604                    local-filename remote-filename sharing basic
605                    external-format)
606  "Create and return a new socket."
607  (declare (dynamic-extent keys))
608  (declare (ignore type connect remote-host remote-port eol format
609                   keepalive reuse-address nodelay broadcast linger
610                   local-port local-host backlog class out-of-band-inline
611                   local-filename remote-filename sharing basic external-format))
612  (ecase address-family
613    ((:file) (apply #'make-file-socket keys))
614    ((nil :internet) (apply #'make-ip-socket keys))))
615
616
617
618(defun make-udp-socket (&rest keys &aux (fd -1))
619  (unwind-protect
620    (let (socket)
621      (setq fd (socket-call nil "socket"
622                            (c_socket #$AF_INET #$SOCK_DGRAM #$IPPROTO_UDP)))
623      (apply #'set-socket-options fd keys)
624      (setq socket (make-instance 'udp-socket
625                                  :device fd
626                                  :keys keys))
627      (setq fd -1)
628      socket)
629    (unless (< fd 0)
630      (fd-close fd))))
631
632(defun make-tcp-socket (&rest keys &key connect &allow-other-keys &aux (fd -1))
633  (unwind-protect
634    (let (socket)
635      (setq fd (socket-call nil "socket"
636                            (c_socket #$AF_INET #$SOCK_STREAM #$IPPROTO_TCP)))
637      (apply #'set-socket-options fd keys)
638      (setq socket
639            (ecase connect
640              ((nil :active) (apply #'make-tcp-stream-socket fd keys))
641              ((:passive) (apply #'make-tcp-listener-socket fd keys))))
642      (setq fd -1)
643      socket)
644    (unless (< fd 0)
645      (fd-close fd))))
646
647(defun make-stream-file-socket (&rest keys &key connect &allow-other-keys &aux (fd -1))
648  (unwind-protect
649    (let (socket)
650      (setq fd (socket-call nil "socket" (c_socket #$PF_LOCAL #$SOCK_STREAM 0)))
651      (apply #'set-socket-options fd keys)
652      (setq socket
653            (ecase connect
654              ((nil :active) (apply #'make-file-stream-socket fd keys))
655              ((:passive) (apply #'make-file-listener-socket fd keys))))
656      (setq fd -1)
657      socket)
658    (unless (< fd 0)
659      (fd-close fd))))
660
661(defun %socket-connect (fd addr addrlen)
662  (let* ((err (c_connect fd addr addrlen)))
663    (declare (fixnum err))
664    (when (eql err (- #$EINPROGRESS))
665      (process-output-wait fd)
666      (setq err (- (int-getsockopt fd #$SOL_SOCKET #$SO_ERROR))))
667    (unless (eql err 0) (socket-error nil "connect" err))))
668   
669(defun inet-connect (fd host-n port-n)
670  (rlet ((sockaddr :sockaddr_in))
671    (setf (pref sockaddr :sockaddr_in.sin_family) #$AF_INET
672          (pref sockaddr :sockaddr_in.sin_port) port-n
673          (pref sockaddr :sockaddr_in.sin_addr.s_addr) host-n)
674    (%socket-connect fd sockaddr (record-length :sockaddr_in))))
675               
676(defun file-socket-connect (fd remote-filename)
677  (rletz ((sockaddr :sockaddr_un))
678    (init-unix-sockaddr sockaddr remote-filename)
679    (%socket-connect fd sockaddr (record-length :sockaddr_un))))
680         
681 
682(defun make-tcp-stream-socket (fd &rest keys
683                                  &key remote-host
684                                  remote-port                             
685                                  &allow-other-keys)
686  (inet-connect fd
687                (host-as-inet-host remote-host)
688                (port-as-inet-port remote-port "tcp"))
689  (apply #'make-tcp-stream fd keys))
690
691(defun make-file-stream-socket (fd &rest keys
692                                   &key remote-filename
693                                   &allow-other-keys)
694  (file-socket-connect fd remote-filename)
695  (apply #'make-file-socket-stream fd keys))
696
697
698(defun make-tcp-stream (fd &key (format :bivalent) external-format (class 'tcp-stream) sharing (basic t) &allow-other-keys)
699  (let* ((external-format (normalize-external-format :socket external-format)))
700    (let ((element-type (ecase format
701                          ((nil :text) 'character)
702                          ((:binary :bivalent) '(unsigned-byte 8)))))
703      ;; TODO: check out fd-stream-advance, -listen, -eofp, -force-output, -close
704      ;; See if should specialize any of 'em.
705      (make-fd-stream fd
706                      :class class
707                      :direction :io
708                      :element-type element-type
709                      :sharing sharing
710                      :character-p (not (eq format :binary))
711                      :encoding (external-format-character-encoding external-format)
712                      :line-termination (external-format-line-termination external-format)
713                      :basic basic))))
714
715(defun make-file-socket-stream (fd &key (format :bivalent) external-format (class 'file-socket-stream)  sharing basic &allow-other-keys)
716  (let* ((external-format (normalize-external-format :socket external-format)))
717 
718    (let ((element-type (ecase format
719                          ((nil :text) 'character)
720                          ((:binary :bivalent) '(unsigned-byte 8)))))
721      ;; TODO: check out fd-stream-advance, -listen, -eofp, -force-output, -close
722      ;; See if should specialize any of 'em.
723      (make-fd-stream fd
724                      :class class
725                      :direction :io
726                      :element-type element-type
727                      :encoding (external-format-character-encoding external-format)
728                      :line-termination (external-format-line-termination external-format)
729                      :sharing sharing
730                      :character-p (not (eq format :binary))
731                      :basic basic))))
732
733(defun make-tcp-listener-socket (fd &rest keys &key backlog &allow-other-keys)
734  (socket-call nil "listen" (c_listen fd (or backlog 5)))
735  (make-instance 'listener-socket
736                 :device fd
737                 :keys keys))
738
739(defun make-file-listener-socket (fd &rest keys &key backlog &allow-other-keys)
740  (socket-call nil "listen" (c_listen fd (or backlog 5)))
741  (make-instance 'file-listener-socket
742                 :device fd
743                 :keys keys))
744
745(defun socket-accept (fd wait socket)
746  (flet ((_accept (fd async)
747           (let ((res (c_accept fd (%null-ptr) (%null-ptr))))
748             (declare (fixnum res))
749             ;; See the inscrutable note under ERROR HANDLING in
750             ;; man accept(2). This is my best guess at what they mean...
751             (if (and async (< res 0)
752                      (or (eql res (- #$ENETDOWN))
753                          (eql res (- #+linux-target #$EPROTO
754                                      #+(or darwin-target freebsd-target) #$EPROTOTYPE))
755                          (eql res (- #$ENOPROTOOPT))
756                          (eql res (- #$EHOSTDOWN))
757                          (eql res (- #+linux-target #$ENONET
758                                      #+(or darwin-target freebsd-target) #$ENETDOWN))
759                          (eql res (- #$EHOSTUNREACH))
760                          (eql res (- #$EOPNOTSUPP))
761                          (eql res (- #$ENETUNREACH))))
762               (- #$EAGAIN)
763               res))))
764    (cond (wait
765            (with-eagain fd :input
766              (_accept fd *multiprocessing-socket-io*)))
767          (*multiprocessing-socket-io*
768            (_accept fd t))
769          (t
770            (let ((old (socket-call socket "fcntl" (fd-get-flags fd))))
771              (unwind-protect
772                  (progn
773                    (socket-call socket "fcntl" (fd-set-flags fd (logior old #$O_NONBLOCK)))
774                    (_accept fd t))
775                (socket-call socket "fcntl" (fd-set-flags fd old))))))))
776
777(defun accept-socket-connection (socket wait stream-create-function)
778  (let ((listen-fd (socket-device socket))
779        (fd -1))
780    (unwind-protect
781      (progn
782        (setq fd (socket-accept listen-fd wait socket))
783        (cond ((>= fd 0)
784               (prog1 (apply stream-create-function fd (socket-keys socket))
785                 (setq fd -1)))
786              ((eql fd (- #$EAGAIN)) nil)
787              (t (socket-error socket "accept" fd))))
788      (when (>= fd 0)
789        (fd-close fd)))))
790
791(defgeneric accept-connection (socket &key wait)
792  (:documentation
793  "Extract the first connection on the queue of pending connections,
794accept it (i.e. complete the connection startup protocol) and return a new
795tcp-stream or file-socket-stream representing the newly established
796connection.  The tcp stream inherits any properties of the listener socket
797that are relevant (e.g. :keepalive, :nodelay, etc.) The original listener
798socket continues to be open listening for more connections, so you can call
799accept-connection on it again."))
800
801(defmethod accept-connection ((socket listener-socket) &key (wait t))
802  (accept-socket-connection socket wait #'make-tcp-stream))
803
804(defmethod accept-connection ((socket file-listener-socket) &key (wait t))
805  (accept-socket-connection socket wait #'make-file-socket-stream))
806
807(defun verify-socket-buffer (buf offset size)
808  (unless offset (setq offset 0))
809  (unless (<= (+ offset size) (length buf))
810    (report-bad-arg size `(integer 0 ,(- (length buf) offset))))
811  (multiple-value-bind (arr start) (array-data-and-offset buf)
812    (setq buf arr offset (+ offset start)))
813  ;; TODO: maybe should allow any raw vector
814  (let ((subtype (typecode buf)))
815    (unless #+ppc32-target (and (<= ppc32::min-8-bit-ivector-subtag subtype)
816                                (<= subtype ppc32::max-8-bit-ivector-subtag))
817            #+ppc64-target (= (the fixnum (logand subtype ppc64::fulltagmask))
818                              ppc64::ivector-class-8-bit)
819            #+x8664-target (and (>= subtype x8664::min-8-bit-ivector-subtag)
820                                (<= subtype x8664::max-8-bit-ivector-subtag))
821      (report-bad-arg buf `(or (array character)
822                               (array (unsigned-byte 8))
823                               (array (signed-byte 8))))))
824  (values buf offset))
825
826(defmethod send-to ((socket udp-socket) msg size
827                    &key remote-host remote-port offset)
828  "Send a UDP packet over a socket."
829  (let ((fd (socket-device socket)))
830    (multiple-value-setq (msg offset) (verify-socket-buffer msg offset size))
831    (unless remote-host
832      (setq remote-host (or (getf (socket-keys socket) :remote-host)
833                            (remote-socket-info socket :host))))
834    (unless remote-port
835      (setq remote-port (or (getf (socket-keys socket) :remote-port)
836                            (remote-socket-info socket :port))))
837    (rlet ((sockaddr :sockaddr_in))
838      (setf (pref sockaddr :sockaddr_in.sin_family) #$AF_INET)
839      (setf (pref sockaddr :sockaddr_in.sin_addr.s_addr)
840            (if remote-host (host-as-inet-host remote-host) #$INADDR_ANY))
841      (setf (pref sockaddr :sockaddr_in.sin_port)
842            (if remote-port (port-as-inet-port remote-port "udp") 0))
843      (%stack-block ((bufptr size))
844        (%copy-ivector-to-ptr msg offset bufptr 0 size)
845        (socket-call socket "sendto"
846          (with-eagain fd :output
847            (c_sendto fd bufptr size 0 sockaddr (record-length :sockaddr_in))))))))
848
849(defmethod receive-from ((socket udp-socket) size &key buffer extract offset)
850  "Read a UDP packet from a socket. If no packets are available, wait for
851a packet to arrive. Returns four values:
852  The buffer with the data
853  The number of bytes read
854  The 32-bit unsigned IP address of the sender of the data
855  The port number of the sender of the data."
856  (let ((fd (socket-device socket))
857        (vec-offset offset)
858        (vec buffer)
859        (ret-size -1))
860    (when vec
861      (multiple-value-setq (vec vec-offset)
862        (verify-socket-buffer vec vec-offset size)))
863    (rlet ((sockaddr :sockaddr_in)
864           (namelen :signed))
865      (setf (pref sockaddr :sockaddr_in.sin_family) #$AF_INET)
866      (setf (pref sockaddr :sockaddr_in.sin_addr.s_addr) #$INADDR_ANY)
867      (setf (pref sockaddr :sockaddr_in.sin_port) 0)
868      (setf (pref namelen :signed) (record-length :sockaddr_in))
869      (%stack-block ((bufptr size))
870        (setq ret-size (socket-call socket "recvfrom"
871                         (with-eagain fd :input
872                           (c_recvfrom fd bufptr size 0 sockaddr namelen))))
873        (unless vec
874          (setq vec (make-array ret-size
875                                :element-type
876                                (ecase (socket-format socket)
877                                  ((:text) 'base-char)
878                                  ((:binary :bivalent) '(unsigned-byte 8))))
879                vec-offset 0))
880        (%copy-ptr-to-ivector bufptr 0 vec vec-offset ret-size))
881      (values (cond ((null buffer)
882                     vec)
883                    ((or (not extract)
884                         (and (eql 0 (or offset 0))
885                              (eql ret-size (length buffer))))
886                     buffer)
887                    (t 
888                     (subseq vec vec-offset (+ vec-offset ret-size))))
889              ret-size
890              (ntohl (pref sockaddr :sockaddr_in.sin_addr.s_addr))
891              (ntohs (pref sockaddr :sockaddr_in.sin_port))))))
892
893(defgeneric shutdown (socket &key direction)
894  (:documentation
895   "Shut down part of a bidirectional connection. This is useful if e.g.
896you need to read responses after sending an end-of-file signal."))
897
898(defmethod shutdown (socket &key direction)
899  ;; TODO: should we ignore ENOTCONN error?  (at least make sure it
900  ;; is a distinct, catchable error type).
901  (let ((fd (socket-device socket)))
902    (socket-call socket "shutdown"
903      (c_shutdown fd (ecase direction
904                       (:input 0)
905                       (:output 1))))))
906
907;; Accepts port as specified by user, returns port number in network byte
908;; order.  Protocol should be one of "tcp" or "udp".  Error if not known.
909(defun port-as-inet-port (port proto)
910  (or (etypecase port
911        (fixnum (htons port))
912        (string (_getservbyname port proto))
913        (symbol (_getservbyname (string-downcase (symbol-name port)) proto)))
914      (socket-error nil "getservbyname" (- #$ENOENT))))
915
916(defun lookup-port (port proto)
917  "Find the port number for the specified port and protocol."
918  (if (fixnump port)
919    port
920    (ntohs (port-as-inet-port port proto))))
921
922;; Accepts host as specified by user, returns host number in network byte
923;; order.
924(defun host-as-inet-host (host)
925  (etypecase host
926    (integer (htonl host))
927    (string (or (and (every #'(lambda (c) (position c ".0123456789")) host)
928                     (_inet_aton host))
929                (multiple-value-bind (addr err) (c_gethostbyname host)
930                  (or addr
931                      (socket-error nil "gethostbyname" err t)))))))
932
933
934(defun dotted-to-ipaddr (name &key (errorp t))
935  "Convert a dotted-string representation of a host address to a 32-bit
936unsigned IP address."
937  (let ((addr (_inet_aton name)))
938    (if addr (ntohl addr)
939      (and errorp (error "Invalid dotted address ~s" name)))))
940   
941(defun lookup-hostname (host)
942  "Convert a host spec in any of the acceptable formats into a 32-bit
943unsigned IP address."
944  (if (typep host 'integer)
945    host
946    (ntohl (host-as-inet-host host))))
947
948(defun ipaddr-to-dotted (addr &key values)
949  "Convert a 32-bit unsigned IP address into octets."
950  (if values
951      (values (ldb (byte 8 24) addr)
952              (ldb (byte 8 16) addr)
953              (ldb (byte 8  8) addr)
954              (ldb (byte 8  0) addr))
955    (_inet_ntoa (htonl addr))))
956
957(defun ipaddr-to-hostname (ipaddr &key ignore-cache)
958  "Convert a 32-bit unsigned IP address into a host name string."
959  (declare (ignore ignore-cache))
960  (multiple-value-bind (name err) (c_gethostbyaddr (htonl ipaddr))
961    (or name (socket-error nil "gethostbyaddr" err t))))
962 
963
964(defun int-getsockopt (socket level optname)
965  (rlet ((valptr :signed)
966         (vallen :signed))
967    (setf (pref vallen :signed) 4)
968    (let* ((err (c_getsockopt socket level optname valptr vallen)))
969      (if (and (eql 0 err)
970               (eql 4 (pref vallen :signed)))
971        (pref valptr :signed)
972        (socket-error socket "getsockopt" err)))))
973
974(defun int-setsockopt (socket level optname optval)
975  (rlet ((valptr :signed))
976    (setf (pref valptr :signed) optval)
977    (socket-call socket "setsockopt"
978      (c_setsockopt socket level optname valptr (record-length :signed)))))
979
980#+(or darwin-target linux-target)
981(defloadvar *h-errno-variable-address* nil)
982#+linux-target
983(defloadvar *h-errno-function-address* nil)
984
985(defun h-errno-location ()
986  #+darwin-target
987  ;; As of Tiger, Darwin doesn't seem to have grasped the concept
988  ;; of thread-local storage for h_errno.
989  (or *h-errno-variable-address*
990      (setq *h-errno-variable-address* (foreign-symbol-address "_h_errno")))
991  ;; Supported versions of FreeBSD seem to have grasped that concept.
992  #+freebsd-target
993  (#_ __h_error)
994  #+linux-target
995  ;; Current versions of Linux support thread-specific h_errno,
996  ;; but older versions may not.
997  (if *h-errno-function-address*
998    (ff-call *h-errno-function-address* :address)
999    (or *h-errno-variable-address*
1000        (let* ((entry (foreign-symbol-entry "__h_errno_location")))
1001          (if entry
1002            (ff-call (setq *h-errno-function-address* entry) :address)
1003            (setq *h-errno-variable-address*
1004                  (foreign-symbol-address  "h_errno")))))))
1005           
1006
1007#+(or darwin-target freebsd-target)
1008(defun c_gethostbyaddr (addr)
1009  (rlet ((addrp :unsigned))
1010    (setf (pref addrp :unsigned) addr)
1011    (without-interrupts
1012     (let* ((hp (#_gethostbyaddr addrp (record-length :unsigned) #$AF_INET)))
1013       (declare (dynamic-extent hp))
1014       (if (not (%null-ptr-p hp))
1015         (%get-cstring (pref hp :hostent.h_name))
1016         (values nil (pref (h-errno-location) :signed)))))))
1017
1018#+linux-target
1019(defun c_gethostbyaddr (addr)
1020  (rlet ((hostent :hostent)
1021         (hp (* (struct :hostent)))
1022         (herr :signed)
1023         (addrp :unsigned))
1024    (setf (pref addrp :unsigned) addr)
1025    (do* ((buflen 1024 (+ buflen buflen))) ()
1026      (declare (fixnum buflen))
1027      (%stack-block ((buf buflen))
1028        (let* ((res (#_gethostbyaddr_r addrp (record-length :unsigned) #$AF_INET
1029                                       hostent buf buflen hp herr)))
1030          (declare (fixnum res))
1031          (unless (eql res #$ERANGE)
1032            (return
1033             (if (and (eql res 0) (not (%null-ptr-p (%get-ptr hp))))
1034                 (%get-cstring (pref (%get-ptr hp) :hostent.h_name))
1035               (values nil (- (pref herr :signed)))))))))))
1036
1037#+(or darwin-target freebsd-target)
1038(defun c_gethostbyname (name)
1039  (with-cstrs ((name (string name)))
1040    (without-interrupts
1041     (let* ((hp (#_gethostbyname  name)))
1042       (declare (dynamic-extent hp))
1043       (if (not (%null-ptr-p hp))
1044         (%get-unsigned-long
1045          (%get-ptr (pref hp :hostent.h_addr_list)))
1046         (values nil (pref (h-errno-location) :signed)))))))
1047
1048#+linux-target
1049(defun c_gethostbyname (name)
1050  (with-cstrs ((name (string name)))
1051    (rlet ((hostent :hostent)
1052           (hp (* (struct :hostent)))
1053           (herr :signed))
1054       (do* ((buflen 1024 (+ buflen buflen))) ()
1055         (declare (fixnum buflen))
1056         (%stack-block ((buf buflen))
1057           (let* ((res (#_gethostbyname_r name hostent buf buflen hp herr)))
1058             (declare (fixnum res))
1059             (unless (eql res #$ERANGE)
1060               (return
1061                 (if (eql res 0)
1062                   (%get-unsigned-long
1063                    (%get-ptr (pref (%get-ptr hp) :hostent.h_addr_list)))
1064                   (values nil (- (pref herr :signed))))))))))))
1065
1066(defun _getservbyname (name proto)
1067  (with-cstrs ((name (string name))
1068               (proto (string proto)))
1069    (let* ((servent-ptr (%null-ptr)))
1070      (declare (dynamic-extent servent-ptr))
1071      (%setf-macptr servent-ptr (#_getservbyname name proto))
1072      (unless (%null-ptr-p servent-ptr)
1073        (pref servent-ptr :servent.s_port)))))
1074
1075#+linuxppc-target
1076(defun _inet_ntoa (addr)
1077  (rlet ((addrp :unsigned))
1078    (setf (pref addrp :unsigned) addr)
1079    (with-macptrs ((p))
1080      (%setf-macptr p (#_inet_ntoa addrp))
1081      (unless (%null-ptr-p p) (%get-cstring p)))))
1082
1083;;; On all of these platforms, the argument is a (:struct :in_addr),
1084;;; a single word that should be passed by value.  The FFI translator
1085;;; seems to lose the :struct, so just using #_ doesn't work (that
1086;;; sounds like a bug in the FFI translator.)
1087#+(or darwin-target linuxx8664-target freebsd-target)
1088(defun _inet_ntoa (addr)
1089  (with-macptrs ((p))
1090    (%setf-macptr p (external-call #+darwin-target "_inet_ntoa"
1091                                   #-darwin-target "inet_ntoa"
1092                                   :unsigned-fullword addr
1093                                   :address))
1094    (unless (%null-ptr-p p) (%get-cstring p))))                           
1095
1096
1097(defun _inet_aton (string)
1098  (with-cstrs ((name string))
1099    (rlet ((addr :in_addr))
1100      (let* ((result #+freebsd-target (#___inet_aton name addr)
1101                     #-freebsd-target (#_inet_aton name addr)))
1102        (unless (eql result 0)
1103          (pref addr :in_addr.s_addr))))))
1104
1105(defun c_socket (domain type protocol)
1106  #-linuxppc-target
1107  (syscall syscalls::socket domain type protocol)
1108  #+linuxppc-target
1109  (rlet ((params (:array :unsigned-long 3)))
1110    (setf (paref params (:* :unsigned-long) 0) domain
1111          (paref params (:* :unsigned-long) 1) type
1112          (paref params (:* :unsigned-long) 2) protocol)
1113    (syscall syscalls::socketcall 1 params)))
1114
1115(defun init-unix-sockaddr (addr path)
1116  (macrolet ((sockaddr_un-path-len ()
1117               (/ (ensure-foreign-type-bits
1118                   (foreign-record-field-type 
1119                    (%find-foreign-record-type-field
1120                     (parse-foreign-type '(:struct :sockaddr_un)) :sun_path)))
1121                  8)))
1122    (let* ((name (native-translated-namestring path))
1123           (namelen (length name))
1124           (pathlen (sockaddr_un-path-len))
1125           (copylen (min (1- pathlen) namelen)))
1126      (setf (pref addr :sockaddr_un.sun_family) #$AF_LOCAL)
1127      (let* ((sun-path (pref addr :sockaddr_un.sun_path)))
1128        (dotimes (i copylen)
1129          (setf (%get-unsigned-byte sun-path i)
1130                (let* ((code (char-code (schar name i))))
1131                  (if (> code 255)
1132                    (char-code #\Sub)
1133                    code))))))))
1134
1135(defun bind-unix-socket (socketfd path)
1136  (rletz ((addr :sockaddr_un))
1137    (init-unix-sockaddr addr path)
1138    (socket-call
1139     nil
1140     "bind"
1141     (c_bind socketfd
1142             addr
1143             (+ 2
1144                (#_strlen
1145                 (pref addr :sockaddr_un.sun_path)))))))
1146     
1147
1148(defun c_bind (sockfd sockaddr addrlen)
1149  #+(or darwin-target linuxx8664-target freebsd-target)
1150  (progn
1151    #+(or darwin-target freebsd-target)
1152    (setf (pref sockaddr :sockaddr_in.sin_len) addrlen)
1153    (syscall syscalls::bind sockfd sockaddr addrlen))
1154  #+linuxppc-target
1155  (progn
1156    #+ppc32-target
1157    (%stack-block ((params 12))
1158      (setf (%get-long params 0) sockfd
1159            (%get-ptr params 4) sockaddr
1160            (%get-long params 8) addrlen)
1161      (syscall syscalls::socketcall 2 params))
1162    #+ppc64-target
1163    (%stack-block ((params 24))
1164      (setf (%%get-unsigned-longlong params 0) sockfd
1165            (%get-ptr params 8) sockaddr
1166            (%%get-unsigned-longlong params 16) addrlen)
1167      (syscall syscalls::socketcall 2 params))))
1168
1169(defun c_connect (sockfd addr len)
1170  #+(or darwin-target linuxx8664-target freebsd-target)
1171  (syscall syscalls::connect sockfd addr len)
1172  #+linuxppc-target
1173  (progn
1174    #+ppc32-target
1175    (%stack-block ((params 12))
1176      (setf (%get-long params 0) sockfd
1177            (%get-ptr params 4) addr
1178            (%get-long params 8) len)
1179      (syscall syscalls::socketcall 3 params))
1180    #+ppc64-target
1181    (%stack-block ((params 24))
1182      (setf (%%get-unsigned-longlong params 0) sockfd
1183            (%get-ptr params 8) addr
1184            (%%get-unsigned-longlong params 16) len)
1185      (syscall syscalls::socketcall 3 params))))
1186
1187(defun c_listen (sockfd backlog)
1188  #+(or darwin-target linuxx8664-target freebsd-target)
1189  (syscall syscalls::listen sockfd backlog)
1190  #+linuxppc-target
1191  (progn
1192    #+ppc32-target
1193    (%stack-block ((params 8))
1194      (setf (%get-long params 0) sockfd
1195            (%get-long params 4) backlog)
1196      (syscall syscalls::socketcall 4 params))
1197    #+ppc64-target
1198    (%stack-block ((params 16))
1199      (setf (%%get-unsigned-longlong params 0) sockfd
1200            (%%get-unsigned-longlong params 8) backlog)
1201      (syscall syscalls::socketcall 4 params))))
1202
1203(defun c_accept (sockfd addrp addrlenp)
1204  #+(or darwin-target linuxx8664-target freebsd-target)
1205  (syscall syscalls::accept sockfd addrp addrlenp)
1206  #+linuxppc-target
1207  (progn
1208    #+ppc32-target
1209    (%stack-block ((params 12))
1210      (setf (%get-long params 0) sockfd
1211            (%get-ptr params 4) addrp
1212            (%get-ptr params 8) addrlenp)
1213      (syscall syscalls::socketcall 5 params))
1214    #+ppc64-target
1215    (%stack-block ((params 24))
1216      (setf (%%get-unsigned-longlong params 0) sockfd
1217            (%get-ptr params 8) addrp
1218            (%get-ptr params 16) addrlenp)
1219      (syscall syscalls::socketcall 5 params))))
1220
1221(defun c_getsockname (sockfd addrp addrlenp)
1222  #+(or darwin-target linuxx8664-target freebsd-target)
1223  (syscall syscalls::getsockname sockfd addrp addrlenp)
1224  #+linuxppc-target
1225  (progn
1226    #+ppc32-target
1227    (%stack-block ((params 12))
1228      (setf (%get-long params 0) sockfd
1229            (%get-ptr params 4) addrp
1230            (%get-ptr params 8) addrlenp)
1231      (syscall syscalls::socketcall 6 params))
1232    #+ppc64-target
1233    (%stack-block ((params 24))
1234      (setf (%%get-unsigned-longlong params 0) sockfd
1235            (%get-ptr params 8) addrp
1236            (%get-ptr params 16) addrlenp)
1237      (syscall syscalls::socketcall 6 params))))
1238
1239(defun c_getpeername (sockfd addrp addrlenp)
1240  #+(or darwin-target linuxx8664-target freebsd-target)
1241  (syscall syscalls::getpeername sockfd addrp addrlenp)
1242  #+linuxppc-target
1243  (progn
1244    #+ppc32-target
1245    (%stack-block ((params 12))
1246      (setf (%get-long params 0) sockfd
1247            (%get-ptr params 4) addrp
1248            (%get-ptr params 8) addrlenp)
1249      (syscall syscalls::socketcall 7 params))
1250    #+ppc64-target
1251    (%stack-block ((params 24))
1252      (setf (%%get-unsigned-longlong params 0) sockfd
1253            (%get-ptr params 8) addrp
1254            (%get-ptr params 16) addrlenp)
1255      (syscall syscalls::socketcall 7 params))))
1256
1257(defun c_socketpair (domain type protocol socketsptr)
1258  #+(or darwin-target linuxx8664-target freebsd-target)
1259  (syscall syscalls::socketpair domain type protocol socketsptr)
1260  #+linuxppc-target
1261  (progn
1262    #+ppc32-target
1263    (%stack-block ((params 16))
1264      (setf (%get-long params 0) domain
1265            (%get-long params 4) type
1266            (%get-long params 8) protocol
1267            (%get-ptr params 12) socketsptr)
1268      (syscall syscalls::socketcall 8 params))
1269    #+ppc64-target
1270    (%stack-block ((params 32))
1271      (setf (%%get-unsigned-longlong params 0) domain
1272            (%%get-unsigned-longlong params 8) type
1273            (%%get-unsigned-longlong params 16) protocol
1274            (%get-ptr params 24) socketsptr)
1275      (syscall syscalls::socketcall 8 params))))
1276
1277
1278
1279(defun c_sendto (sockfd msgptr len flags addrp addrlen)
1280  #+(or darwin-target linuxx8664-target freebsd-target)
1281  (syscall syscalls::sendto sockfd msgptr len flags addrp addrlen)
1282  #+linuxppc-target
1283  (progn
1284    #+ppc32-target
1285    (%stack-block ((params 24))
1286      (setf (%get-long params 0) sockfd
1287            (%get-ptr params  4) msgptr
1288            (%get-long params 8) len
1289            (%get-long params 12) flags
1290            (%get-ptr params  16) addrp
1291            (%get-long params 20) addrlen)
1292      (syscall syscalls::socketcall 11 params))
1293    #+ppc64-target
1294    (%stack-block ((params 48))
1295      (setf (%%get-unsigned-longlong params 0) sockfd
1296            (%get-ptr params  8) msgptr
1297            (%%get-unsigned-longlong params 16) len
1298            (%%get-unsigned-longlong params 24) flags
1299            (%get-ptr params  32) addrp
1300            (%%get-unsigned-longlong params 40) addrlen)
1301      (syscall syscalls::socketcall 11 params))))
1302
1303(defun c_recvfrom (sockfd bufptr len flags addrp addrlenp)
1304  #+(or darwin-target linuxx8664-target freebsd-target)
1305  (syscall syscalls::recvfrom sockfd bufptr len flags addrp addrlenp)
1306  #+linuxppc-target
1307  (progn
1308    #+ppc32-target
1309    (%stack-block ((params 24))
1310      (setf (%get-long params 0) sockfd
1311            (%get-ptr params  4) bufptr
1312            (%get-long params 8) len
1313            (%get-long params 12) flags
1314            (%get-ptr params  16) addrp
1315            (%get-ptr params  20) addrlenp)
1316      (syscall syscalls::socketcall 12 params))
1317    #+ppc64-target
1318    (%stack-block ((params 48))
1319      (setf (%get-long params 0) sockfd
1320            (%get-ptr params  8) bufptr
1321            (%get-long params 16) len
1322            (%get-long params 24) flags
1323            (%get-ptr params  32) addrp
1324            (%get-ptr params  40) addrlenp)
1325      (syscall syscalls::socketcall 12 params))))
1326
1327(defun c_shutdown (sockfd how)
1328  #+(or darwin-target linuxx8664-target freebsd-target)
1329  (syscall syscalls::shutdown sockfd how)
1330  #+linuxppc-target
1331  (progn
1332    #+ppc32-target
1333    (%stack-block ((params 8))
1334      (setf (%get-long params 0) sockfd
1335            (%get-long params 4) how)
1336      (syscall syscalls::socketcall 13 params))
1337    #+ppc64-target
1338    (%stack-block ((params 16))
1339      (setf (%%get-unsigned-longlong params 0) sockfd
1340            (%%get-unsigned-longlong params 8) how)
1341      (syscall syscalls::socketcall 13 params))))
1342
1343(defun c_setsockopt (sockfd level optname optvalp optlen)
1344  #+(or darwin-target linuxx8664-target freebsd-target)
1345  (syscall syscalls::setsockopt sockfd level optname optvalp optlen)
1346  #+linuxppc-target
1347  (progn
1348    #+ppc32-target
1349    (%stack-block ((params 20))
1350      (setf (%get-long params 0) sockfd
1351            (%get-long params 4) level
1352            (%get-long params 8) optname
1353            (%get-ptr params 12) optvalp
1354            (%get-long params 16) optlen)
1355      (syscall syscalls::socketcall 14 params))
1356    #+ppc64-target
1357    (%stack-block ((params 40))
1358      (setf (%%get-unsigned-longlong params 0) sockfd
1359            (%%get-unsigned-longlong params 8) level
1360            (%%get-unsigned-longlong params 16) optname
1361            (%get-ptr params 24) optvalp
1362            (%%get-unsigned-longlong params 32) optlen)
1363      (syscall syscalls::socketcall 14 params))))
1364
1365(defun c_getsockopt (sockfd level optname optvalp optlenp)
1366  #+(or darwin-target linuxx8664-target freebsd-target)
1367  (syscall syscalls::getsockopt sockfd level optname optvalp optlenp)
1368  #+linuxppc-target
1369  (progn
1370    #+ppc32-target
1371    (%stack-block ((params 20))
1372      (setf (%get-long params 0) sockfd
1373            (%get-long params 4) level
1374            (%get-long params 8) optname
1375            (%get-ptr params 12) optvalp
1376            (%get-ptr params 16) optlenp)
1377      (syscall syscalls::socketcall 15 params))
1378    #+ppc64-target
1379    (%stack-block ((params 40))
1380      (setf (%%get-unsigned-longlong params 0) sockfd
1381            (%%get-unsigned-longlong params 8) level
1382            (%%get-unsigned-longlong params 16) optname
1383            (%get-ptr params 24) optvalp
1384            (%get-ptr params 32) optlenp)
1385      (syscall syscalls::socketcall 15 params))))
1386
1387(defun c_sendmsg (sockfd msghdrp flags)
1388  #+(or darwin-target linuxx8664-target freebsd-target)
1389  (syscall syscalls::sendmsg sockfd msghdrp flags)
1390  #+linuxppc-target
1391  (progn
1392    #+ppc32-target
1393    (%stack-block ((params 12))
1394      (setf (%get-long params 0) sockfd
1395            (%get-ptr params 4) msghdrp
1396            (%get-long params 8) flags)
1397      (syscall syscalls::socketcall 16 params))
1398    #+ppc64-target
1399    (%stack-block ((params 24))
1400      (setf (%%get-unsigned-longlong params 0) sockfd
1401            (%get-ptr params 8) msghdrp
1402            (%%get-unsigned-longlong params 16) flags)
1403      (syscall syscalls::socketcall 16 params))))
1404
1405(defun c_recvmsg (sockfd msghdrp flags)
1406  #+(or darwin-target linuxx8664-target freebsd-target)
1407  (syscall syscalls::recvmsg sockfd msghdrp flags)
1408  #+linuxppc-target
1409  (progn
1410    #+ppc32-target
1411    (%stack-block ((params 12))
1412      (setf (%get-long params 0) sockfd
1413            (%get-ptr params 4) msghdrp
1414            (%get-long params 8) flags)
1415      (syscall syscalls::socketcall 17 params))
1416    #+ppc64-target
1417    (%stack-block ((params 24))
1418      (setf (%%get-unsigned-longlong params 0) sockfd
1419            (%get-ptr params 8) msghdrp
1420            (%%get-unsigned-longlong params 16) flags)
1421      (syscall syscalls::socketcall 17 params))))
1422
1423;;; Return a list of currently configured interfaces, a la ifconfig.
1424(defstruct ip-interface
1425  name
1426  addr
1427  netmask
1428  flags
1429  address-family)
1430
1431(defun dump-buffer (p n)
1432  (dotimes (i n (progn (terpri) (terpri)))
1433    (unless (logtest i 15)
1434      (format t "~&~8,'0x: " (%ptr-to-int (%inc-ptr p i))))
1435    (format t " ~2,'0x" (%get-byte p i))))
1436
1437(defun %get-ip-interfaces ()
1438  (rlet ((p :address (%null-ptr)))
1439    (if (zerop (#_getifaddrs p))
1440      (unwind-protect
1441           (do* ((q (%get-ptr p) (pref q :ifaddrs.ifa_next))
1442                 (res ()))
1443                ((%null-ptr-p q) (nreverse res))
1444             (let* ((addr (pref q :ifaddrs.ifa_addr)))
1445               (when (and (not (%null-ptr-p addr))
1446                          (eql (pref addr :sockaddr.sa_family) #$AF_INET))
1447                 (push (make-ip-interface
1448                                   :name (%get-cstring (pref q :ifaddrs.ifa_name))
1449                                   :addr (pref addr :sockaddr_in.sin_addr.s_addr)
1450                                   :netmask (pref (pref q :ifaddrs.ifa_netmask)
1451                                                  :sockaddr_in.sin_addr.s_addr)
1452                                   :flags (pref q :ifaddrs.ifa_flags)
1453                                   :address-family #$AF_INET)
1454                       res))))
1455        (#_freeifaddrs (pref p :address))))))
1456
1457
1458(defloadvar *ip-interfaces* ())
1459
1460(defun ip-interfaces ()
1461  (or *ip-interfaces*
1462      (setq *ip-interfaces* (%get-ip-interfaces))))
1463
1464;;; This should presumably happen after a configuration change.
1465;;; How do we detect a configuration change ?
1466(defun %reset-ip-interfaces ()
1467  (setq *ip-interfaces* ()))
1468
1469;;; Return the first non-loopback interface that's up and whose address
1470;;; family is #$AF_INET.  If no such interface exists, return
1471;;; the loopback interface.
1472(defun primary-ip-interface ()
1473  (let* ((ifaces (ip-interfaces)))
1474    (or (find-if #'(lambda (i)
1475                     (and (eq #$AF_INET (ip-interface-address-family i))
1476                          (let* ((flags (ip-interface-flags i)))
1477                            (and (not (logtest #$IFF_LOOPBACK flags))
1478                                 (logtest #$IFF_UP flags)))))
1479                 ifaces)
1480        (car ifaces))))
1481
1482(defun primary-ip-interface-address ()
1483  (let* ((iface (primary-ip-interface)))
1484    (if iface
1485      (ip-interface-addr iface)
1486      (error "Can't determine primary IP interface"))))
1487         
1488         
1489(defmethod stream-io-error ((stream socket) errno where)
1490  (socket-error stream where errno))
Note: See TracBrowser for help on using the repository browser.